File Coverage

blib/lib/Net/IP/Match.pm

Criterion	Covered	Total	%
statement	13	13	100.0
branch			n/a
condition			n/a
subroutine	5	5	100.0
pod			n/a
total	18	18	100.0

use 5.008;
use strict;
use warnings;

package Net::IP::Match;
BEGIN {
  $Net::IP::Match::VERSION = '1.101700';
}

# ABSTRACT: Efficiently match IP addresses against IP ranges
use Filter::Simple;
FILTER sub {
    s[\b __MATCH_IP \s* \( (.*?) \s* , \s* (.*?) \s* \) ]
     [
        my @n = eval $2;
        my @t;
        for (@n) {
            my ($quad, $bits) = m!^(\d+\.\d+\.\d+\.\d+)(?:/(\d+))?!g;
            my $matchbits = 32 - ($bits || 32);
            my $int = unpack("N", pack("C4", split(/\./, $quad)));
            my $mask = $int >> $matchbits;
            push @t => { mask => $mask, bits => $matchbits };
        }

        my $unpack_code = qq!unpack("N", pack("C4", split(/\\./, $1)))!;

        # if there's only one ip range to match against, we don't need
        # the temp variable and the do-block, so it's even faster

        if (@t == 1) {
            local $_ = shift @t;
            "($_->{mask} == $unpack_code" .
            ($_->{bits} ? " >> $_->{bits}" : "") . ")"
        } else {
            my $var = '$__tmp_match_ip';
            my $cond = join ' || ' => map { "$_->{mask} == $var" .
            ($_->{bits} ? " >> $_->{bits}" : "") } @t;
            qq!do { my $var = $unpack_code; $cond }!
        }

     ]gsex;
    print if $::debug;
};
1;


__END__