File Coverage

blib/lib/Net/IMP/SessionLog.pm

Criterion	Covered	Total	%
statement	27	59	45.7
branch	0	14	0.0
condition	0	7	0.0
subroutine	9	13	69.2
pod	3	4	75.0
total	39	97	40.2

use strict;
use warnings;

package Net::IMP::SessionLog;
use base 'Net::IMP::Base';
use fields qw(fh conn);

use Net::IMP; # import IMP_ constants
use Net::IMP::Debug;
use Carp 'croak';
use Time::HiRes 'gettimeofday';
use File::Temp 'tempfile';

sub INTERFACE { return (
    [
	undef,             # all types/protocols are supported
	[
	    IMP_PREPASS,   # nothing gets ever changed or denied
	    IMP_ACCTFIELD, # to account the session log file
	]
    ]
)}

sub validate_cfg {
    my ($class,%args) = @_;
    my @err;
    my $fmt = delete $args{format} || 'bin';
    if ( $fmt eq 'pcap' ) {
	push @err, "cannot load Net::PcapWriter needed for format pcap: $@"
	    if ! eval "require Net::PcapWriter";
    } elsif ( $fmt ne 'bin' ) {
	push @err, "format should be bin or pcap"
    }

    my $dir = delete $args{dir};
    push @err, "no dir given" if ! $dir;

    push @err,$class->SUPER::validate_cfg(%args);
    return @err;
}


# create new context object
#  - open log file
#  - prepare initial and only results (PREPASS in both directions)
sub new_analyzer {
    my ($factory,%args) = @_;

    my $dir = $factory->{factory_args}{dir};
    my $fmt = $factory->{factory_args}{format} || 'bin';

    my $meta = $args{meta};
    my ($fh,$fname) = tempfile(
	sprintf("%d-%s.%s-%s.%s-XXXXX", time(),
	    @{$meta}{qw(caddr cport saddr sport)}),
	SUFFIX => ".$fmt",
	DIR => $dir,
    ) or croak("cannot create tmpfile: $!");
    $DEBUG && debug("new context with filename $fname");

    binmode($fh);
    $fh->autoflush(1);

    my $conn = $fmt eq 'pcap'
	&& Net::PcapWriter->new($fh)
	->tcp_conn( @{$meta}{qw(caddr cport saddr sport)} );

    my $analyzer = $factory->SUPER::new_analyzer( %args );
    $analyzer->{fh} = $fh;
    $analyzer->{conn} = $conn;

    # only results for both directions + acct
    $analyzer->add_results(
	[ IMP_ACCTFIELD,'logfile',$fname ],
	[ IMP_PREPASS,0,IMP_MAXOFFSET ],
	[ IMP_PREPASS,1,IMP_MAXOFFSET ]
    );

    return $analyzer;
}

sub data {
    my ($analyzer,$dir,$data) = @_;
    if ( my $c = $analyzer->{conn} ) {
	# pcap format
	$c->write($dir,$data,[gettimeofday()]);
    } else {
	# bin format
	print {$analyzer->{fh}} pack("NNcN/a*",gettimeofday(),$dir,$data);
    }
    $analyzer->run_callback;
}

1;

__END__