File Coverage

blib/lib/Net/FreeIPA/Response.pm

Criterion	Covered	Total	%
statement	43	43	100.0
branch	8	8	100.0
condition	3	5	60.0
subroutine	12	12	100.0
pod	5	5	100.0
total	71	73	97.2

package Net::FreeIPA::Response;
$Net::FreeIPA::Response::VERSION = '3.0.2';
use strict;
use warnings;

use base qw(Exporter);

use Net::FreeIPA::Error;

our @EXPORT = qw(mkresponse);

use overload bool => '_boolean';

use Readonly;

Readonly my $RESULT_PATH => 'result/result';

=head1 NAME

Net::FreeIPA::Response is an response class for Net::FreeIPA.

Boolean logic is overloaded using C<_boolean> method (as inverse of C).

=head2 Public methods

=over

=item mkresponse

A C factory

=cut

sub mkresponse
{
    return Net::FreeIPA::Response->new(@_);
}


=item new

Create new response instance.

Options

=over

=item answer: complete answer hashref

=item error: an error (passed to C).

=item result_path: passed to C to set the result attribute.

=back

=cut

sub new
{
    my ($this, %opts) = @_;
    my $class = ref($this) || $this;
    my $self = {
        answer => $opts{answer} || {},
    };
    bless $self, $class;

    # First error
    $self->set_error($opts{error});
    # Then result
    $self->set_result($opts{result_path});

    return $self;
};

=item set_error

Set and return the error attribute using C.

=cut

sub set_error
{
    my $self = shift;
    $self->{error} = mkerror(@_);
    return $self->{error};
}

=item set_result

Set and return the result attribute based on the C.

The C is path-like string, indicating which subtree of the answer
should be set as result attribute (default C).

=cut

sub set_result
{
    my ($self, $result_path) = @_;

    my $res;

    if (! $self->is_error()) {
        $result_path = $RESULT_PATH if ! defined($result_path);

        $res = $self->{answer};
        # remove any "empty" paths
        foreach my $subpath (grep {$_} split('/', $result_path)) {
            $res = $res->{$subpath} if (defined($res));
        };
    };

    $self->{result} = $res;

    return $self->{result};
};

=item is_error

Test if this is an error or not (based on error attribute).

=cut

sub is_error
{
    my $self = shift;
    return $self->{error} ? 1 : 0;
}

# Overloaded boolean, inverse of is_error
sub _boolean
{
    my $self = shift;
    return ! $self->is_error();
}

=pod

=back

=cut

1;