File Coverage

blib/lib/Net/Frame/Layer/RIP/v2.pm

Criterion	Covered	Total	%
statement	58	66	87.8
branch	13	22	59.0
condition			n/a
subroutine	14	15	93.3
pod	8	8	100.0
total	93	111	83.7

#
# $Id: v2.pm 49 2009-05-31 13:15:34Z VinsWorldcom $
#
package Net::Frame::Layer::RIP::v2;
use strict; use warnings;

use Net::Frame::Layer qw(:consts :subs);
our @ISA = qw(Net::Frame::Layer Exporter);

our %EXPORT_TAGS = (
   consts => [qw(
      NF_RIP_V2_ADDRESSFAMILY_IPV4
      NF_RIP_V2_ADDRESSFAMILY_AUTH
      NF_RIP_V2_AUTHTYPE_SIMPLE
      NF_RIP_V2_METRIC_INFINITY
   )],
);
our @EXPORT_OK = (
   @{$EXPORT_TAGS{consts}},
);

use constant NF_RIP_V2_ADDRESSFAMILY_IPV4 => 2;
use constant NF_RIP_V2_ADDRESSFAMILY_AUTH => 0xffff;
use constant NF_RIP_V2_AUTHTYPE_SIMPLE    => 2;
use constant NF_RIP_V2_METRIC_INFINITY    => 16;

our @AS = qw(
   addressFamily
   routeTag
   address
   subnetMask
   nextHop
   metric
   authType
   authentication
);
__PACKAGE__->cgBuildIndices;
__PACKAGE__->cgBuildAccessorsScalar(\@AS);

sub new {
   shift->SUPER::new(
      addressFamily => NF_RIP_V2_ADDRESSFAMILY_IPV4,
      routeTag      => 0,
      address       => '0.0.0.0',
      subnetMask    => '0.0.0.0',
      nextHop       => '0.0.0.0',
      metric        => 1,
      @_,
   );
}

sub full {
   shift->SUPER::new(
      addressFamily => 0,
      routeTag      => 0,
      address       => '0.0.0.0',
      subnetMask    => '0.0.0.0',
      nextHop       => '0.0.0.0',
      metric        => NF_RIP_V2_METRIC_INFINITY,
      @_,
   );
}

sub auth {
   my $self = shift;

   my %params = (
      authentication => ''
   );

   my %args = @_;
   for (keys(%args)) {
      if (/^authentication$/i) {
         $params{'authentication'} = substr $args{$_}, 0, 16
      }
   }

   $self->SUPER::new(
      addressFamily  => NF_RIP_V2_ADDRESSFAMILY_AUTH,
      authType       => NF_RIP_V2_AUTHTYPE_SIMPLE,
      authentication => '',
      @_,
      %params,
   );
}

sub getLength { 20 }

sub pack {
   my $self = shift;

   if ($self->addressFamily == NF_RIP_V2_ADDRESSFAMILY_AUTH) {
      $self->raw($self->SUPER::pack('nna16',
         $self->addressFamily,
         $self->authType,
         $self->authentication
      )) or return;

   } else {
      $self->raw($self->SUPER::pack('nna4a4a4N',
         $self->addressFamily,
         $self->routeTag,
         inetAton($self->address),
         inetAton($self->subnetMask),
         inetAton($self->nextHop),
         $self->metric
      )) or return;
   }

   return $self->raw;
}

sub unpack {
   my $self = shift;

   my ($addressFamily, $remain) =
      $self->SUPER::unpack('n a*', $self->raw)
         or return;

   if ($addressFamily == NF_RIP_V2_ADDRESSFAMILY_AUTH) {
      my ($authType, $authentication, $payload) =
         $self->SUPER::unpack('na16 a*', $remain)
            or return;

      $self->addressFamily($addressFamily);
      $self->authType($authType);
      $authentication =~ s/\0{0,}$//g;
      $self->authentication($authentication);

      $self->payload($payload);

   } else {
      my ($routeTag, $address, $subnetMask, $nextHop, $metric, $payload) =
         $self->SUPER::unpack('na4a4a4N a*', $remain)
            or return;

      $self->addressFamily($addressFamily);
      $self->routeTag($routeTag);
      $self->address(inetNtoa($address));
      $self->subnetMask(inetNtoa($subnetMask));
      $self->nextHop(inetNtoa($nextHop));
      $self->metric($metric);

      $self->payload($payload);
   }

   return $self;
}

sub encapsulate {
   my $self = shift;

   return $self->nextLayer if $self->nextLayer;

   if ($self->payload) {
      return "RIP::v2";
   }

   NF_LAYER_NONE;
}

sub print {
   my $self = shift;

   my $l = $self->layer;
   my $buf;

   if ($self->addressFamily == NF_RIP_V2_ADDRESSFAMILY_AUTH) {
      $buf = sprintf
         "$l: addressFamily:0x%02x  authType:%d\n".
         "$l: authentication:%s",
            $self->addressFamily, $self->authType,
            $self->authentication;

   } else {
      $buf = sprintf
         "$l: addressFamily:%d  routeTag:%d\n".
         "$l: address:%s  subnetMask:%s  nextHop:%s\n".
         "$l: metric:%d",
            $self->addressFamily, $self->routeTag,
            $self->address, $self->subnetMask, $self->nextHop,
            $self->metric;
   }

   return $buf;
}

1;

__END__