File Coverage

blib/lib/Net/Frame/Layer/OSPF/Lsa/Network.pm

Criterion	Covered	Total	%
statement	12	39	30.7
branch	0	8	0.0
condition	0	3	0.0
subroutine	4	9	44.4
pod	5	5	100.0
total	21	64	32.8

#
# $Id: Network.pm,v 1.1 2007/02/25 20:36:23 gomor Exp $
#
package Net::Frame::Layer::OSPF::Lsa::Network;
use strict;
use warnings;

use Net::Frame::Layer qw(:consts :subs);
our @ISA = qw(Net::Frame::Layer);

our @AS = qw(
   netmask
);
our @AA = qw(
   routerList
);
__PACKAGE__->cgBuildIndices;
__PACKAGE__->cgBuildAccessorsScalar(\@AS);
__PACKAGE__->cgBuildAccessorsArray (\@AA);

use Net::Frame::Layer::OSPF qw(:consts);

sub new {
   shift->SUPER::new(
      netmask    => '255.255.255.0',
      routerList => [],
      @_,
   );
}

sub getLength {
   my $self = shift;
   my $len = 4;
   $len += 4 for $self->routerList;
   $len;
}

sub pack {
   my $self = shift;

   my $raw = $self->SUPER::pack('a4', inetAton($self->netmask))
      or return undef;

   for ($self->routerList) {
      $raw .= $self->SUPER::pack('a4', inetAton($_))
         or return undef;
   }

   $self->raw($raw);
}

sub unpack {
   my $self = shift;

   my ($netmask, $payload) = $self->SUPER::unpack('a4 a*', $self->raw)
      or return undef;

   $self->netmask(inetNtoa($netmask));

   my @routerList;
   while ($payload && length($payload) > 3) {
      my $ip;
      ($ip, $payload) = $self->SUPER::unpack('a4 a*', $payload)
         or return undef;
      push @routerList, inetNtoa($ip);
   }
   $self->routerList(\@routerList);

   $self->payload($payload);

   $self;
}

sub print {
   my $self = shift;

   my $l = $self->layer;
   my $buf = sprintf
      "$l: netmask:%s",
         $self->netmask,
   ;

   for ($self->routerList) {
      $buf .= sprintf "\n$l: router: %s", $_;
   }

   $buf;
}

1;

__END__