File Coverage

blib/lib/Net/Frame/Layer/DNS/Question.pm

Criterion	Covered	Total	%
statement	37	42	88.1
branch	4	10	40.0
condition			n/a
subroutine	10	11	90.9
pod	6	6	100.0
total	57	69	82.6

#
# $Id: Question.pm 49 2009-05-31 13:15:34Z VinsWorldcom $
#
package Net::Frame::Layer::DNS::Question;
use strict; use warnings;

use Net::Frame::Layer qw(:consts :subs);
our @ISA = qw(Net::Frame::Layer Exporter);

use Net::Frame::Layer::DNS::Constants qw(:consts);
my @consts;
for my $c (sort(keys(%constant::declared))) {
    if ($c =~ /^Net::Frame::Layer::DNS::Constants::/) {
        $c =~ s/^Net::Frame::Layer::DNS::Constants:://;
        push @consts, $c
    }
}
our %EXPORT_TAGS = (
   consts => [@consts]
);
our @EXPORT_OK = (
   @{$EXPORT_TAGS{consts}},
);

our @AS = qw(
   name
   type
   class
);
__PACKAGE__->cgBuildIndices;
__PACKAGE__->cgBuildAccessorsScalar(\@AS);

use Net::Frame::Layer::DNS qw(:subs);

sub new {
   shift->SUPER::new(
      name  => '',
      type  => NF_DNS_TYPE_A,
      class => NF_DNS_CLASS_IN,
      @_,
   );
}

sub getLength {
   my $self = shift;

   # 1 byte leading length, name, 1 byte trailing null, 2 bytes type, 2 bytes class
   if (length($self->name) == 0) {
      return length($self->name) + 5
   } else {
      return length($self->name) + 6
   }
}

sub pack {
   my $self = shift;

   my $name = dnsAton($self->name);

   $self->raw($self->SUPER::pack('H* nn',
      $name, $self->type, $self->class,
   )) or return;

   return $self->raw;
}

sub unpack {
   my $self = shift;

   my @parts = split /\0/, $self->raw, 2;
   my ($name) = dnsNtoa($parts[0]);

   my ($type, $class, $payload) =
      $self->SUPER::unpack('nn a*', $parts[1])
         or return;

   $self->name($name);
   $self->type($type);
   $self->class($class);
   $self->payload($payload);

   return $self;
}

sub encapsulate {
   my $self = shift;

   return $self->nextLayer if $self->nextLayer;

   if ($self->payload) {
      return 'DNS::RR';
   }

   NF_LAYER_NONE;
}

sub print {
   my $self = shift;

   my $l = $self->layer;
   my $buf = sprintf
      "$l: name:%s\n".
      "$l: type:%d  class:%d",
         $self->name,
         $self->type, $self->class;

   return $buf;
}

1;

__END__