File Coverage

blib/lib/Net/Frame/Layer/CDP/PortId.pm

Criterion	Covered	Total	%
statement	29	35	82.8
branch	3	6	50.0
condition			n/a
subroutine	8	10	80.0
pod	6	6	100.0
total	46	57	80.7

#
# $Id: PortId.pm 1640 2013-03-28 17:58:27Z VinsWorldcom $
#
package Net::Frame::Layer::CDP::PortId;
use strict; use warnings;

use Net::Frame::Layer qw(:consts :subs);
our @ISA = qw(Net::Frame::Layer);

our @AS = qw(
   type
   length
   portId
);
__PACKAGE__->cgBuildIndices;
__PACKAGE__->cgBuildAccessorsScalar(\@AS);

#no strict 'vars';

use Net::Frame::Layer::CDP::Constants qw(:consts);

sub new {
   shift->SUPER::new(
      type   => NF_CDP_TYPE_PORT_ID,
      length => 19,
      portId => 'FastEthernet1/0',
      @_,
   );
}

sub getLength {
   my $self = shift;

   my $length = 4 + length($self->portId);

   return $length
}

sub pack {
   my $self = shift;

   my $raw = $self->SUPER::pack('nna*',
      $self->type,
      $self->length,
      $self->portId,
   ) or return;

   return $self->raw($raw);
}

sub unpack {
   my $self = shift;

   my ($type, $length, $tail) =
      $self->SUPER::unpack('nna*', $self->raw)
         or return;

   $self->type($type);
   $self->length($length);

   my $valLen = $length - 4;
   my ($portId, $payload) =
      $self->SUPER::unpack("a$valLen a*", $tail)
         or return;

   $self->portId($portId);
   $self->payload($payload);

   return $self;
}

sub computeLengths {
   my $self = shift;

   $self->length(4 + length($self->portId));

   return 1;
}

sub print {
   my $self = shift;

   my $l = $self->layer;
   my $buf = sprintf
      "$l: type:0x%04x  length:%d  portId:%s",
         $self->type, $self->length, $self->portId;

   return $buf;
}

1;

__END__