File Coverage

blib/lib/Net/FTP/Path/Iter/Entry.pm

Criterion	Covered	Total	%
statement	54	59	91.5
branch	16	26	61.5
condition			n/a
subroutine	14	14	100.0
pod	1	1	100.0
total	85	100	85.0

package Net::FTP::Path::Iter::Entry;

use 5.010;

# ABSTRACT: Class representing a Filesystem Entry

use strict;
use warnings;

our $VERSION = '0.05';

use Carp;
use Fcntl qw[ :mode ];

use File::Listing qw[ parse_dir ];

use namespace::clean;

use overload
  '-X'   => '_statit',
  'bool' => sub { 1 },
  '""'   => sub { $_[0]->{path} },
  ;

use Class::Tiny qw[
  name type size mtime mode parent server path
], { _has_attrs => 0 };










sub BUILD {

    my $self = shift;
    $self->_retrieve_attrs
      unless $self->_has_attrs;
}

sub _statit {

    my $self = shift;
    my $op   = shift;

    $self->_retrieve_attrs
      unless $self->_has_attrs;

    if    ( $op eq 'd' ) { return $self->is_dir }

    elsif ( $op eq 'f' ) { return $self->is_file }

    elsif ( $op eq 's' ) { return $self->size }

    elsif ( $op eq 'z' ) { return $self->size != 0 }

    elsif ( $op eq 'r' ) { return S_IROTH & $self->mode }

    elsif ( $op eq 'R' ) { return S_IROTH & $self->mode }

    elsif ( $op eq 'l' ) { return 0 }

    else { croak( "unsupported file test: -$op\n" ) }

}

sub _get_entries {

    my ( $self, $path ) = @_;

    my $server = $self->server;

    my $pwd = $server->pwd;

    # on some ftp servers, if $path is a symbolic link, dir($path)
    # willl return a listing of $path's own entry, not of its
    # contents.  as a work around, explicitly cwd($path),
    # get the listing, then restore the working directory

    my @entries;
    eval {
        $server->cwd( $path )
          or croak( "unable to chdir to ", $path, "\n" );

        my $listing = $server->dir( '.' )
          or croak( "error listing $path" );

        for my $entry ( parse_dir( $listing ) ) {

            my %attr;
            @attr{qw[ name type size mtime mode]} = @$entry;
            $attr{parent}                         = $path;
            $attr{_has_attrs}                     = 1;

            push @entries, \%attr;

        }
    };

    my $err = $@;

    $server->cwd( $pwd )
      or croak( "unable to return to directory: $pwd\n" );

    croak( $err ) if $err;


    return \@entries;

}

#
# This file is part of Net-FTP-Path-Iter
#
# This software is Copyright (c) 2017 by Smithsonian Astrophysical Observatory.
#
# This is free software, licensed under:
#
#   The GNU General Public License, Version 3, June 2007
#

1;

__END__