File Coverage

blib/lib/Net/Evernote/Simple.pm

Criterion	Covered	Total	%
statement	10	12	83.3
branch			n/a
condition			n/a
subroutine	4	4	100.0
pod			n/a
total	14	16	87.5

###########################################
package Net::Evernote::Simple;
###########################################

use strict;
use warnings;

use Net::Evernote::Simple::EDAMUserStore::Constants;
use Net::Evernote::Simple::EDAMUserStore::Types;
use Net::Evernote::Simple::EDAMUserStore::UserStore;
use Net::Evernote::Simple::EDAMNoteStore::NoteStore;
use Net::Evernote::Simple::EDAMNoteStore::Types;
use Net::Evernote::Simple::EDAMErrors::Types;
use Net::Evernote::Simple::EDAMTypes::Types;
use Log::Log4perl qw(:easy);
use YAML qw( LoadFile );
use File::Basename;
use File::Temp qw( tempfile );
use Thrift;
use Thrift::HttpClient;
use Thrift::BinaryProtocol;
use Data::Dumper;

our $VERSION = "0.07";

our $EN_DEV_TOKEN_PAGE =
    "http://dev.evernote.com/documentation/cloud/chapters/" .
    "Authentication.php#devtoken";

###########################################
sub new {
###########################################
    my($class, %options) = @_;

    my $self = {
        evernote_host => "www.evernote.com",
        dev_token           => undef,
        config_file         => undef,
        consumer_key        => undef,
        thrift_send_timeout => 10000,
        thrift_recv_timeout => 75000,
        %options,
    };

    bless $self, $class;

    if( !defined $self->{ consumer_key } ) {
        ( my $dashed_pkg = __PACKAGE__ ) =~ s/::/-/g;
        $self->{ consumer_key } = lc $dashed_pkg;
    }

    if( ! defined $self->{ config_file } ) {
        my( $home ) = glob "~";
        $self->{ config_file } = "$home/.evernote.yml";
    }

    if( !defined $self->{ dev_token } ) {
        if( -f $self->{ config_file } ) {
            my $data = LoadFile $self->{ config_file };
            if( exists $data->{ dev_token } ) {
                $self->{ dev_token } = $data->{ dev_token };
            }
        }
    }

    my $user_store_uri =
        "https://$self->{ evernote_host }/edam/user";

    my $http_client = $self->thrift_http_client( $user_store_uri );
    my $protocol =
        Thrift::BinaryProtocol->new( $http_client );

    $self->{ client } =
        Net::Evernote::Simple::EDAMUserStore::UserStoreClient->new( $protocol );

    return $self;
}

###########################################
sub init {
###########################################
    my( $self ) = @_;

    if( $self->{ init_done } ) {
        return 1;
    }

    if( !defined $self->{ dev_token } ) {
        LOGDIE "Developer token argument 'dev_token' missing. ",
            "Check $EN_DEV_TOKEN_PAGE on how to obtain one.";
    }

    if( ! $self->version_check() ) {
        LOGDIE "Version check failed";
    }

    $self->{ init_done } = 1;
}

###########################################
sub dev_token {
###########################################
    my( $self ) = @_;

    return $self->{ dev_token };
}

###########################################
sub thrift_http_client {
###########################################
    my( $self, $uri ) = @_;

    my $client = Thrift::HttpClient->new( $uri );

      # Timeouts can't be passed into Thrift::HttpClient's constructor,
      # so we set them manually here. Thrift's default values
      # are in the millisecond range and therefore completely out
      # of whack unless you have the Evernote server on your LAN.
    $client->setSendTimeout( $self->{ thrift_send_timeout } );
    $client->setRecvTimeout( $self->{ thrift_recv_timeout } );

    return $client;
}

###########################################
sub note_store {
###########################################
    my( $self ) = @_;

    $self->init();

    my $note_store_uri;

    eval {
        $note_store_uri =
          $self->{ client }->getNoteStoreUrl( $self->{ dev_token } );
    };

    if( $@ ) {
        ERROR Dumper( $@ );
        return undef;
    }

    my $note_store_client = $self->thrift_http_client( $note_store_uri );

    my $note_store_protocol = Thrift::BinaryProtocol->new(
       $note_store_client );

    my $note_store =
      Net::Evernote::Simple::EDAMNoteStore::NoteStoreClient->new(
        $note_store_protocol );

    return $note_store;
}

###########################################
sub version_check {
###########################################
    my( $self ) = @_;

    eval {
      my $version_ok =
        $self->{ client }->checkVersion( $self->{ consumer_key },
          Net::Evernote::Simple::EDAMUserStore::Constants::EDAM_VERSION_MAJOR,
          Net::Evernote::Simple::EDAMUserStore::Constants::EDAM_VERSION_MINOR,
        );

      INFO "Version check returned: $version_ok";
    };

    if( $@ ) {
        LOGWARN Dumper( $@ );
        $self->horrid_thrift_client_error_diagnostics( $self->{client} );
        return 0;
    }

    return 1;
}

###########################################
sub horrid_thrift_client_error_diagnostics {
###########################################
    my( $self, $client ) = @_;

    # Apparently, there's no way to figure out what went wrong at the
    # http level once a thrift call fails, except poking around in thrift's
    # internal structures. Oh, the humanity!

    eval {
        my $in = $client->{input}->{trans}->{in};
        $in->setpos(0);
        LOGWARN join '', <$in>;
    };

    if( $@ ) {
        LOGWARN "Unable to diagnose underlying error";
    }
}

###########################################
sub sdk {
###########################################
    my( $self, $name ) = @_;

    return __PACKAGE__ . "::" . $name;
}

1;

__END__