File Coverage

blib/lib/Net/Easypost.pm

Criterion	Covered	Total	%
statement	42	49	85.7
branch	8	10	80.0
condition	1	3	33.3
subroutine	12	14	85.7
pod	5	5	100.0
total	68	81	83.9

package Net::Easypost;
$Net::Easypost::VERSION = '0.20';
use Carp qw(croak);

use Net::Easypost::Address;
use Net::Easypost::Label;
use Net::Easypost::Parcel;
use Net::Easypost::Rate;
use Net::Easypost::Request;
use Net::Easypost::Shipment;

use Moo;
use namespace::autoclean;

# ABSTRACT: Perl client for the Easypost web service



has 'requester' => (
    is      => 'ro',
    lazy    => 1,
    default => sub { return Net::Easypost::Request->new }
);


sub verify_address {
    my ($self, $params) = @_;

    if ( ref($params) eq 'HASH' ) {
        return Net::Easypost::Address->new( $params )->verify;
    }
    elsif ( ref($params) eq 'Net::Easypost::Address' ) {
        return $params->verify;
    }
    else {
        croak "verify_address expects either a hashref or an instance of Net::Easypost::Address\n";
    }
}


sub get_rates {
    my $self = shift; # shift is important here

    my $params;
    if ( scalar @_ == 1 ) {
        if ( ref( $_[0] ) ne 'HASH' ) {
            croak 'get_rates expects a hashref not a '. ref($params) .'\n';
        }
        else {
            $params = shift;
        }
    }
    else {
        $params = { @_ };
    }

    return Net::Easypost::Shipment->new(
        to_address   => $params->{to},
        from_address => $params->{from},
        parcel       => $params->{parcel},
    )->rates;
}


sub buy_label {
    my ($self, $shipment, %options) = @_;

    croak 'Buy label expects a parameter of type Net::Easypost::Shipment'
        unless $shipment || ref($shipment) ne 'Net::Easypost::Shipment';

    return $shipment->buy(%options);
}


sub get_label {
    my ($self, $label_filename) = @_;

    my $resp = $self->requester->post(
        '/postage/get',
        { label_file_name => $label_filename }
    );

    return Net::Easypost::Label->new(
        rate          => Net::Easypost::Rate->new( $resp->{rate} ),
        tracking_code => $resp->{tracking_code},
        filename      => $resp->{label_file_name},
        filetype      => $resp->{label_file_type},
        url           => $resp->{label_url}
    );
}


sub list_labels {
    my ($self) = @_;

    my $resp = $self->requester->get(
        $self->requester->_build_url('/postage/list')
    );

    return $resp->{postages};
}


1;

__END__