File Coverage

blib/lib/Net/DRI/Protocol/EPP/Extensions/ResellerInfo.pm

Criterion	Covered	Total	%
statement	12	64	18.7
branch	0	28	0.0
condition	0	6	0.0
subroutine	4	12	33.3
pod	0	7	0.0
total	16	117	13.6

## Domain Registry Interface, Reseller Extension Mapping for EPP
##
## Copyright (c) 2015 Patrick Mevzek . All rights reserved.
##
## This file is part of Net::DRI
##
## Net::DRI is free software; you can redistribute it and/or modify
## it under the terms of the GNU General Public License as published by
## the Free Software Foundation; either version 2 of the License, or
## (at your option) any later version.
##
## See the LICENSE file that comes with this distribution for more details.
####################################################################################################

package Net::DRI::Protocol::EPP::Extensions::ResellerInfo;

use strict;
use warnings;

use Net::DRI::Util;
use Net::DRI::Exception;

####################################################################################################

sub register_commands
{
 my ($class,$version)=@_;
 my %dhc = ( info   => [ undef, \&info_parse ],
             create => [ \&create_build, undef ],
             update => [ \&update_build, undef ] );

 return { 'domain' => \%dhc, 'host' => \%dhc, 'contact' => \%dhc };
}

sub setup
{
 my ($class,$po,$version)=@_;
 $po->ns({ 'resellerext' => [ 'urn:ietf:params:xml:ns:resellerext-1.0','resellerext-1.0.xsd' ] });
 return;
}

sub capabilities_add { return ('domain_update','reseller',[qw/add del set/]); }

sub implements { return 'https://tools.ietf.org/html/draft-zhou-eppext-reseller-00'; }

####################################################################################################

sub info_parse
{
 my ($po,$otype,$oaction,$oname,$rinfo)=@_;
 my $mes=$po->message();
 return unless $mes->is_success();

 my $data=$mes->get_extension($mes->ns('resellerext'),'infData');
 return unless defined $data;

 my %r;
 foreach my $el (Net::DRI::Util::xml_list_children($data))
 {
  my ($name,$node)=@$el;
  if ($name eq 'resID')
  {
   $r{id}=$node->textContent();
  } elsif ($name eq 'resName')
  {
   $r{name}=$node->textContent();
  }
 }

 $rinfo->{$otype}->{$oname}->{reseller}=\%r;

 return;
}

sub _add_info
{
 my ($rd)=@_;
 my @r;
 Net::DRI::Exception::usererr_insufficient_parameters('Missing reseller id') unless Net::DRI::Util::has_key($rd,'id');
 Net::DRI::Exception::usererr_invalid_parameters('Invalid syntax for reseller id: '.$rd->{id}) unless Net::DRI::Util::xml_is_token($rd->{id},3,16);
 push @r,['resellerext:resID',$rd->{id}];

 if (Net::DRI::Util::has_key($rd,'name'))
 {
  Net::DRI::Exception::usererr_invalid_parameters('Invalid syntax for reseller name: '.$rd->{name}) unless length $rd->{name};
  push @r,['resellerext:resName',$rd->{name}];
 }

 return @r;
}

sub create_build
{
 my ($epp,$domain,$rd)=@_;
 my $mes=$epp->message();

 return unless Net::DRI::Util::has_key($rd,'reseller');
 my @d=_add_info($rd->{reseller});

 my $eid=$mes->command_extension_register('resellerext','create');
 $mes->command_extension($eid,\@d);

 return;
}

sub update_build
{
 my ($epp,$domain,$todo,$rp)=@_;

 my $add=$todo->add('reseller');
 my $del=$todo->del('reseller');
 my $set=$todo->set('reseller');

 return unless defined $add || defined $del || defined $set;
 Net::DRI::Exception::usererr_invalid_parameters('Incompatible changeset for reseller: only add or del or set') if 1 < grep { defined } ($add,$del,$set);

 my @n;
 push @n,['resellerext:add',_add_info($add)] if defined $add;
 push @n,['resellerext:rem',_add_info($del)] if defined $del;
 push @n,['resellerext:chg',_add_info($set)] if defined $set;

 my $mes=$epp->message();
 my $eid=$mes->command_extension_register('resellerext','update');
 $mes->command_extension($eid,\@n);
 return;
}


####################################################################################################
1;

__END__