File Coverage

blib/lib/Net/DNS/SEC.pm

Criterion	Covered	Total	%
statement	28	28	100.0
branch	2	2	100.0
condition	2	2	100.0
subroutine	8	8	100.0
pod	3	3	100.0
total	43	43	100.0

package Net::DNS::SEC;

use strict;
use warnings;
use Carp;

our $SVNVERSION = (qw$Id: SEC.pm 1939 2023-09-12 13:34:55Z willem $)[2];
our $VERSION;
$VERSION = '1.22';

use base qw(Exporter DynaLoader);

eval { __PACKAGE__->bootstrap($VERSION) };
warn "\n\n$@\n" if $@;

use Net::DNS 1.01 qw(:DEFAULT);

our @EXPORT = ( @Net::DNS::EXPORT, qw(algorithm digtype key_difference) );


=head1 NAME

Net::DNS::SEC - DNSSEC extensions to Net::DNS

=head1 SYNOPSIS

    use Net::DNS::SEC;

=head1 DESCRIPTION

Net::DNS::SEC is installed as an extension to an existing Net::DNS
installation providing packages to support DNSSEC as specified in
RFC4033, RFC4034, RFC4035 and related documents.

It also provides support for SIG0 which is useful for dynamic updates.

Implements cryptographic signature generation and verification functions
using RSA, DSA, ECDSA, and Edwards curve algorithms.

The extended features are made available by replacing Net::DNS by
Net::DNS::SEC in the use declaration.

=cut


=head1 UTILITY FUNCTIONS

=head2 algorithm

    $mnemonic = algorithm( 5 );
    $numeric  = algorithm( 'RSA-SHA1' );
    print "algorithm mnemonic\t", $mnemonic, "\n";
    print "algorithm number:\t",  $numeric,  "\n";

algorithm() provides conversions between an algorithm code number and
the corresponding mnemonic.

=cut

sub algorithm { return &Net::DNS::RR::DS::algorithm; }


=head2 digtype

    $mnemonic = digtype( 2 );
    $numeric  = digtype( 'SHA-256' );
    print "digest type mnemonic\t", $mnemonic, "\n";
    print "digest type number:\t",  $numeric,  "\n";

digtype() provides conversions between a digest type number and the
corresponding mnemonic.

=cut

sub digtype { return &Net::DNS::RR::DS::digtype; }


=head2 key_difference

    @result = key_difference( \@a, \@b );

Fills @result with all keys in array @a that are not in array @b.

=cut

sub key_difference {
	my $a = shift;
	my $b = shift;
	my $r = shift || [];		## 0.17 API

	local $SIG{__DIE__};
	my ($x) = grep { !$_->isa('Net::DNS::RR::DNSKEY') } @$a, @$b;
	croak sprintf( 'unexpected %s object in key list', ref $x ) if $x;

	my %index = map { ( $_->privatekeyname => 1 ) } @$b;
	return @$r = grep { !$index{$_->privatekeyname} } @$a;
}


########################################

foreach (qw(DS CDS RRSIG)) {
	Net::DNS::RR->new( type => $_ );			# pre-load to access class methods
}

1;
__END__