File Coverage

blib/lib/Net/DNS/RR/EUI48.pm

Criterion	Covered	Total	%
statement	26	26	100.0
branch	4	4	100.0
condition			n/a
subroutine	9	9	100.0
pod	1	1	100.0
total	40	40	100.0

package Net::DNS::RR::EUI48;

use strict;
use warnings;
our $VERSION = (qw$Id: EUI48.pm 1896 2023-01-30 12:59:25Z willem $)[2];

use base qw(Net::DNS::RR);


=head1 NAME

Net::DNS::RR::EUI48 - DNS EUI48 resource record

=cut

use integer;


sub _decode_rdata {			## decode rdata from wire-format octet string
	my ( $self, $data, $offset ) = @_;

	$self->{address} = unpack "\@$offset a6", $$data;
	return;
}


sub _encode_rdata {			## encode rdata as wire-format octet string
	my $self = shift;

	return pack 'a6', $self->{address};
}


sub _format_rdata {			## format rdata portion of RR string.
	my $self = shift;

	return $self->address;
}


sub _parse_rdata {			## populate RR from rdata in argument list
	my ( $self, @argument ) = @_;

	$self->address(@argument);
	return;
}


sub address {
	my ( $self, $address ) = @_;
	$self->{address} = pack 'C6', map { hex($_) } split /[:-]/, $address if $address;
	return defined(wantarray) ? join( '-', unpack 'H2H2H2H2H2H2', $self->{address} ) : undef;
}


1;
__END__