File Coverage

blib/lib/Net/DNS/RR/DHCID.pm

Criterion	Covered	Total	%
statement	44	44	100.0
branch			n/a
condition	6	6	100.0
subroutine	12	12	100.0
pod	3	3	100.0
total	65	65	100.0

package Net::DNS::RR::DHCID;

use strict;
use warnings;
our $VERSION = (qw$Id: DHCID.pm 1896 2023-01-30 12:59:25Z willem $)[2];

use base qw(Net::DNS::RR);


=head1 NAME

Net::DNS::RR::DHCID - DNS DHCID resource record

=cut

use integer;

use MIME::Base64;


sub _decode_rdata {			## decode rdata from wire-format octet string
	my ( $self, $data, $offset ) = @_;

	my $size = $self->{rdlength} - 3;
	@{$self}{qw(identifiertype digesttype digest)} = unpack "\@$offset nC a$size", $$data;
	return;
}


sub _encode_rdata {			## encode rdata as wire-format octet string
	my $self = shift;

	return pack 'nC a*', map { $self->$_ } qw(identifiertype digesttype digest);
}


sub _format_rdata {			## format rdata portion of RR string.
	my $self = shift;

	my @rdata = split /\s+/, encode_base64( $self->_encode_rdata );
	return @rdata;
}


sub _parse_rdata {			## populate RR from rdata in argument list
	my ( $self, @argument ) = @_;

	my $data = MIME::Base64::decode( join "", @argument );
	my $size = length($data) - 3;
	@{$self}{qw(identifiertype digesttype digest)} = unpack "n C a$size", $data;
	return;
}


#	+------------------+------------------------------------------------+
#	|  Identifier Type | Identifier					    |
#	|	Code	   |						    |
#	+------------------+------------------------------------------------+
#	|      0x0000	   | The 1-octet 'htype' followed by 'hlen' octets  |
#	|		   | of 'chaddr' from a DHCPv4 client's DHCPREQUEST |
#	|		   | [7].					    |
#	|      0x0001	   | The data octets (i.e., the Type and	    |
#	|		   | Client-Identifier fields) from a DHCPv4	    |
#	|		   | client's Client Identifier option [10].	    |
#	|      0x0002	   | The client's DUID (i.e., the data octets of a  |
#	|		   | DHCPv6 client's Client Identifier option [11]  |
#	|		   | or the DUID field from a DHCPv4 client's	    |
#	|		   | Client Identifier option [6]).		    |
#	|  0x0003 - 0xfffe | Undefined; available to be assigned by IANA.   |
#	|      0xffff	   | Undefined; RESERVED.			    |
#	+------------------+------------------------------------------------+


sub identifiertype {
	my ( $self, @value ) = @_;
	for (@value) { $self->{identifiertype} = 0 + $_ }
	return $self->{identifiertype} || 0;
}


sub digesttype {
	my ( $self, @value ) = @_;
	for (@value) { $self->{digesttype} = 0 + $_ }
	return $self->{digesttype} || 0;
}


sub digest {
	my ( $self, @value ) = @_;
	for (@value) { $self->{digest} = $_ }
	return $self->{digest} || "";
}


1;
__END__