File Coverage

blib/lib/Net/DNS/Update.pm

Criterion	Covered	Total	%
statement	39	39	100.0
branch	6	6	100.0
condition			n/a
subroutine	9	9	100.0
pod	3	3	100.0
total	57	57	100.0

package Net::DNS::Update;

use strict;
use warnings;

our $VERSION = (qw$Id: Update.pm 1895 2023-01-16 13:38:08Z willem $)[2];


=head1 NAME

Net::DNS::Update - DNS dynamic update packet

=head1 SYNOPSIS

    use Net::DNS;

    $update = Net::DNS::Update->new( 'example.com', 'IN' );

    $update->push( prereq => nxrrset('host.example.com. AAAA') );
    $update->push( update => rr_add('host.example.com. 86400 AAAA 2001::DB8::F00') );

=head1 DESCRIPTION

Net::DNS::Update is a subclass of Net::DNS::Packet, to be used for
making DNS dynamic updates.

Programmers should refer to RFC2136 for dynamic update semantics.

=cut


use integer;
use Carp;

use base qw(Net::DNS::Packet);

use Net::DNS::Resolver;


=head1 METHODS

=head2 new

    $update = Net::DNS::Update->new;
    $update = Net::DNS::Update->new( 'example.com' );
    $update = Net::DNS::Update->new( 'example.com', 'IN' );

Returns a Net::DNS::Update object suitable for performing a DNS
dynamic update.	 Specifically, it creates a packet with the header
opcode set to UPDATE and the zone record type to SOA (per RFC 2136,
Section 2.3).

Programs must use the push() method to add RRs to the prerequisite
and update sections before performing the update.

Arguments are the zone name and the class.  The zone and class may
be undefined or omitted and default to the default domain from the
resolver configuration and IN respectively.

=cut

sub new {
	my ( $class, $zone, @rrclass ) = @_;

	my ($domain) = grep { defined && length } ( $zone, Net::DNS::Resolver->searchlist );

	my $self = __PACKAGE__->SUPER::new( $domain, 'SOA', @rrclass );

	my $header = $self->header;
	$header->opcode('UPDATE');
	$header->qr(0);
	$header->rd(0);

	return $self;
}


=head2 push

    $ancount = $update->push( prereq => $rr );
    $nscount = $update->push( update => $rr );
    $arcount = $update->push( additional => $rr );

    $nscount = $update->push( update => $rr1, $rr2, $rr3 );
    $nscount = $update->push( update => @rr );

Adds RRs to the specified section of the update packet.

Returns the number of resource records in the specified section.

Section names may be abbreviated to the first three characters.

=cut

sub push {
	my ( $self, $section, @rr ) = @_;
	my ($zone) = $self->zone;
	my $zclass = $zone->zclass;
	for (@rr) { $_->class( $_->class =~ /ANY|NONE/ ? () : $zclass ) }
	return $self->SUPER::push( $section, @rr );
}


=head2 unique_push

    $ancount = $update->unique_push( prereq => $rr );
    $nscount = $update->unique_push( update => $rr );
    $arcount = $update->unique_push( additional => $rr );

    $nscount = $update->unique_push( update => $rr1, $rr2, $rr3 );
    $nscount = $update->unique_push( update => @rr );

Adds RRs to the specified section of the update packet provided
that the RRs are not already present in the same section.

Returns the number of resource records in the specified section.

Section names may be abbreviated to the first three characters.

=cut

sub unique_push {
	my ( $self, $section, @rr ) = @_;
	my ($zone) = $self->zone;
	my $zclass = $zone->zclass;
	for (@rr) { $_->class( $_->class =~ /ANY|NONE/ ? () : $zclass ) }
	return $self->SUPER::unique_push( $section, @rr );
}


1;

__END__