File Coverage

blib/lib/Net/DNS/RR/PX.pm

Criterion	Covered	Total	%
statement	45	45	100.0
branch	4	4	100.0
condition	2	2	100.0
subroutine	12	12	100.0
pod	3	3	100.0
total	66	66	100.0

package Net::DNS::RR::PX;

use strict;
use warnings;
our $VERSION = (qw$Id: PX.pm 1898 2023-02-15 14:27:22Z willem $)[2];

use base qw(Net::DNS::RR);


=head1 NAME

Net::DNS::RR::PX - DNS PX resource record

=cut

use integer;

use Net::DNS::DomainName;


sub _decode_rdata {			## decode rdata from wire-format octet string
	my ( $self, $data, $offset ) = @_;

	$self->{preference} = unpack( "\@$offset n", $$data );
	( $self->{map822},  $offset ) = Net::DNS::DomainName2535->decode( $data, $offset + 2 );
	( $self->{mapx400}, $offset ) = Net::DNS::DomainName2535->decode( $data, $offset );
	return;
}


sub _encode_rdata {			## encode rdata as wire-format octet string
	my ( $self, $offset, @opaque ) = @_;

	my $mapx400 = $self->{mapx400};
	my $rdata   = pack( 'n', $self->{preference} );
	$rdata .= $self->{map822}->encode( $offset + 2, @opaque );
	$rdata .= $mapx400->encode( $offset + length($rdata), @opaque );
	return $rdata;
}


sub _format_rdata {			## format rdata portion of RR string.
	my $self = shift;

	my @rdata = ( $self->preference, $self->{map822}->string, $self->{mapx400}->string );
	return @rdata;
}


sub _parse_rdata {			## populate RR from rdata in argument list
	my ( $self, @argument ) = @_;

	for (qw(preference map822 mapx400)) { $self->$_( shift @argument ) }
	return;
}


sub preference {
	my ( $self, @value ) = @_;
	for (@value) { $self->{preference} = 0 + $_ }
	return $self->{preference} || 0;
}


sub map822 {
	my ( $self, @value ) = @_;
	for (@value) { $self->{map822} = Net::DNS::DomainName2535->new($_) }
	return $self->{map822} ? $self->{map822}->name : undef;
}


sub mapx400 {
	my ( $self, @value ) = @_;
	for (@value) { $self->{mapx400} = Net::DNS::DomainName2535->new($_) }
	return $self->{mapx400} ? $self->{mapx400}->name : undef;
}


my $function = sub {			## sort RRs in numerically ascending order.
	return $Net::DNS::a->{'preference'} <=> $Net::DNS::b->{'preference'};
};

__PACKAGE__->set_rrsort_func( 'preference', $function );

__PACKAGE__->set_rrsort_func( 'default_sort', $function );


1;
__END__