File Coverage

blib/lib/Net/DNS/RR/MX.pm

Criterion	Covered	Total	%
statement	42	42	100.0
branch	2	2	100.0
condition	2	2	100.0
subroutine	12	12	100.0
pod	2	2	100.0
total	60	60	100.0

package Net::DNS::RR::MX;

use strict;
use warnings;
our $VERSION = (qw$Id: MX.pm 1896 2023-01-30 12:59:25Z willem $)[2];

use base qw(Net::DNS::RR);


=head1 NAME

Net::DNS::RR::MX - DNS MX resource record

=cut

use integer;

use Net::DNS::DomainName;


sub _decode_rdata {			## decode rdata from wire-format octet string
	my ( $self, @argument ) = @_;
	my ( $data, $offset, @opaque ) = @argument;

	$self->{preference} = unpack( "\@$offset n", $$data );
	$self->{exchange}   = Net::DNS::DomainName1035->decode( $data, $offset + 2, @opaque );
	return;
}


sub _encode_rdata {			## encode rdata as wire-format octet string
	my ( $self,   @argument ) = @_;
	my ( $offset, @opaque )	  = @argument;

	my $exchange = $self->{exchange};
	return pack 'n a*', $self->preference, $exchange->encode( $offset + 2, @opaque );
}


sub _format_rdata {			## format rdata portion of RR string.
	my $self = shift;

	my $exchange = $self->{exchange};
	return join ' ', $self->preference, $exchange->string;
}


sub _parse_rdata {			## populate RR from rdata in argument list
	my ( $self, @argument ) = @_;

	for (qw(preference exchange)) { $self->$_( shift @argument ) }
	return;
}


sub _defaults {				## specify RR attribute default values
	my $self = shift;

	$self->preference(10);
	return;
}


sub preference {
	my ( $self, @value ) = @_;
	for (@value) { $self->{preference} = 0 + $_ }
	return $self->{preference} || 0;
}


sub exchange {
	my ( $self, @value ) = @_;
	for (@value) { $self->{exchange} = Net::DNS::DomainName1035->new($_) }
	return $self->{exchange} ? $self->{exchange}->name : undef;
}


my $function = sub {			## sort RRs in numerically ascending order.
	return $Net::DNS::a->{'preference'} <=> $Net::DNS::b->{'preference'};
};

__PACKAGE__->set_rrsort_func( 'preference', $function );

__PACKAGE__->set_rrsort_func( 'default_sort', $function );


1;
__END__