File Coverage

blib/lib/Net/DNS/RR/CSYNC.pm

Criterion	Covered	Total	%
statement	53	53	100.0
branch	8	8	100.0
condition	4	4	100.0
subroutine	14	14	100.0
pod	5	5	100.0
total	84	84	100.0

package Net::DNS::RR::CSYNC;

use strict;
use warnings;
our $VERSION = (qw$Id: CSYNC.pm 1910 2023-03-30 19:16:30Z willem $)[2];

use base qw(Net::DNS::RR);


=head1 NAME

Net::DNS::RR::CSYNC - DNS CSYNC resource record

=cut

use integer;

use Net::DNS::RR::NSEC;


sub _decode_rdata {			## decode rdata from wire-format octet string
	my ( $self, $data, $offset ) = @_;

	my $limit = $offset + $self->{rdlength};
	@{$self}{qw(soaserial flags)} = unpack "\@$offset Nn", $$data;
	$offset += 6;
	$self->{typebm} = substr $$data, $offset, $limit - $offset;
	return;
}


sub _encode_rdata {			## encode rdata as wire-format octet string
	my $self = shift;

	return pack 'N n a*', $self->soaserial, $self->flags, $self->{typebm};
}


sub _format_rdata {			## format rdata portion of RR string.
	my $self = shift;

	my @rdata = ( $self->soaserial, $self->flags, $self->typelist );
	return @rdata;
}


sub _parse_rdata {			## populate RR from rdata in argument list
	my ( $self, @argument ) = @_;

	$self->soaserial( shift @argument );
	$self->flags( shift @argument );
	$self->typelist(@argument);
	return;
}


sub soaserial {
	my ( $self, @value ) = @_;
	for (@value) { $self->{soaserial} = 0 + $_ }
	return $self->{soaserial} || 0;
}


sub flags {
	my ( $self, @value ) = @_;
	for (@value) { $self->{flags} = 0 + $_ }
	return $self->{flags} || 0;
}


sub immediate {
	my ( $self, @value ) = @_;
	for ( $self->{flags} |= 0 ) {
		if ( scalar @value ) {
			$_ |= 0x0001;
			$_ ^= 0x0001 unless shift @value;
		}
	}
	return $self->{flags} & 0x0001;
}


sub soaminimum {
	my ( $self, @value ) = @_;
	for ( $self->{flags} |= 0 ) {
		if ( scalar @value ) {
			$_ |= 0x0002;
			$_ ^= 0x0002 unless shift @value;
		}
	}
	return $self->{flags} & 0x0002;
}


sub typelist {
	return &Net::DNS::RR::NSEC::typelist;
}


1;
__END__