File Coverage

blib/lib/Net/Curl/Simple/Form.pm

Criterion	Covered	Total	%
statement	10	12	83.3
branch			n/a
condition			n/a
subroutine	4	4	100.0
pod			n/a
total	14	16	87.5

package Net::Curl::Simple::Form;

use strict;
use warnings;
use Scalar::Util qw(looks_like_number);
use Net::Curl::Form;
use base qw(Net::Curl::Form);

our $VERSION = '0.13';

{
	my %optcache;

	sub add
	{
		my $form = shift;

		my @args;
		while ( my ( $opt, $val ) = splice @_, 0, 2 ) {
			unless ( looks_like_number( $opt ) ) {
				# convert option name to option number
				unless ( exists $optcache{ $opt } ) {
					eval '$optcache{ $opt } = '
						. "Net::Curl::Form::CURLFORM_COPY\U$opt";
					eval '$optcache{ $opt } = '
						. "Net::Curl::Form::CURLFORM_\U$opt"
						if $@;
					die "unrecognized literal option: $opt\n"
						if $@;
				}
				$opt = $optcache{ $opt };
			}

			push @args, $opt, $val;
		}

		$form->SUPER::add( @args );

		# allow chaining
		return $form;
	}
}

sub contents
{
	my ( $form, $name, $contents ) = @_;
	$form->add( name => $name, contents => $contents );
}

sub file
{
	my $form = shift;
	$form->add( name => shift, map +( file => $_ ), @_ );
}

1;

__END__