File Coverage

blib/lib/Net/Azure/EventHubs.pm

Criterion	Covered	Total	%
statement	66	66	100.0
branch	8	8	100.0
condition	14	14	100.0
subroutine	17	17	100.0
pod	2	2	100.0
total	107	107	100.0

package Net::Azure::EventHubs;
use 5.008001;
use strict;
use warnings;

use Net::Azure::EventHubs::Request;
use Net::Azure::Authorization::SAS;
use JSON;
use LWP::UserAgent;
use URI;
use Carp;
use Try::Tiny;

use Class::Accessor::Lite (
    new => 0,
    ro  => [qw[
        agent
        timeout
        serializer
        api_version
        authorizer
    ]],
);

our $VERSION              = "0.09";
our $DEFAULT_API_VERSION  = '2014-01';
our $DEFAULT_TIMEOUT      = 60;

sub new {
    my ($class, %param)   = @_;

    $param{agent}         = LWP::UserAgent->new(agent => sprintf('%s/%s', $class, $VERSION));
    $param{serializer}    = JSON->new->utf8(1);
    $param{api_version} ||= $DEFAULT_API_VERSION;
    $param{timeout}     ||= $DEFAULT_TIMEOUT;

    if (!defined $param{authorizer}) {
        my $authorizer = try {
            Net::Azure::Authorization::SAS->new(connection_string => $param{connection_string})
        } catch {
            croak $_;
        };
        $param{authorizer} = $authorizer;
    }

    bless {%param}, $class;
}

sub _uri {
    my ($self, $path, %params) = @_;
    $path ||= '/';
    my $uri = URI->new($self->authorizer->endpoint);
    $uri->scheme('https');
    $uri->path($path);
    $uri->query_form(%params);
    $uri;
}

sub _req {
    my ($self, $path, $payload, %params) = @_;
    croak 'path is reuired'        if !defined $path;
    croak 'payload is required'    if !defined $payload;
    croak 'payload is not hashref' if ref($payload) ne 'HASH';
    $params{timeout}     ||= $self->timeout;
    $params{api_version} ||= $self->api_version;
    my $uri  = $self->_uri($path, %params);
    my $auth = $self->authorizer->token($uri->as_string);
    my $data = $self->serializer->encode($payload);
    my $req  = Net::Azure::EventHubs::Request->new(
        POST => $uri->as_string,
        [
            'Authorization' => $auth,
            'Content-Type'  => 'application/atom+xml;type=entry;charset=utf-8',
        ],
        $data,
    );
    $req->agent($self->agent);
    $req;
}

sub message {
    my ($self, $payload) = @_;
    my $path = sprintf "/%s/messages", $self->authorizer->{entity_path};
    my $req = $self->_req($path => $payload);
    $req;
}


1;
__END__