File Coverage

blib/lib/Narada/Config.pm

Criterion	Covered	Total	%
statement	63	72	87.5
branch	13	18	72.2
condition	3	9	33.3
subroutine	17	17	100.0
pod	4	4	100.0
total	100	120	83.3

package Narada::Config;

use warnings;
use strict;
use Carp;

our $VERSION = 'v2.3.7';

use Export::Attrs;
use Narada;
use Path::Tiny 0.053;

use constant NARADA     => eval { local $SIG{__DIE__}; Narada::detect() } || q{};
use constant DB_DIR     => NARADA eq 'narada-1' ? 'db' : 'mysql';
use constant MAXPERM    => 0666; ## no critic (ProhibitLeadingZeros)

my $VAR_NAME = qr{\A(?:(?![.][.]?/)[\w.-]+/)*(?![.][.]?\z)[\w.-]+\z}xms;


sub get_config :Export {
    my ($var) = @_;
    croak 'Usage: get_config(NAME)' if @_ != 1;
    $var =~ /$VAR_NAME/xms              or croak "Bad config: $var";
    return undef if !NARADA;    ## no critic (ProhibitExplicitReturnUndef)
    return path("config/$var")->slurp_utf8;
}

sub get_config_line :Export {
    my ($val) = get_config(@_);
    return $val if !defined $val;
    $val =~ s/\n\s*\z//xms;
    croak 'Config contain more than one line' if $val =~ /\n/xms;
    return $val;
}

sub get_db_config :Export {
    my %db;
    $db{db} = eval { get_config_line(DB_DIR.'/db') };
    if (!defined $db{db} || !length $db{db}) {
        return;
    }
    $db{login}= get_config_line(DB_DIR.'/login');
    $db{pass} = get_config_line(DB_DIR.'/pass');
    $db{host} = eval { get_config_line(DB_DIR.'/host') } || q{};
    $db{port} = eval { get_config_line(DB_DIR.'/port') } || q{};
    $db{dsn_nodb}  = 'dbi:mysql:';
    $db{dsn_nodb} .= ';host='.$db{host} if $db{host}; ## no critic (ProhibitPostfixControls)
    $db{dsn_nodb} .= ';port='.$db{port} if $db{port}; ## no critic (ProhibitPostfixControls)
    $db{dsn} = $db{dsn_nodb}.';database='.$db{db};
    return \%db;
}

sub set_config :Export {
    my ($var, $val) = @_;
    croak 'Usage: set_config(NAME, VALUE)' if @_ != 2;
    $var =~ /$VAR_NAME/xms              or croak "Bad config: $var";
    croak 'Narada::Config was loaded not in narada directory' if !NARADA;
    my $cfg = path("config/$var");
    $cfg->parent->mkpath;
    $cfg->spew_utf8($val);
    $cfg->chmod(MAXPERM & ~umask);
    return;
}


1; # Magic true value required at end of module
__END__