File Coverage

blib/lib/NNexus/Job.pm

Criterion	Covered	Total	%
statement	13	15	86.6
branch			n/a
condition			n/a
subroutine	5	5	100.0
pod			n/a
total	18	20	90.0

# /=====================================================================\ #
# |  NNexus Autolinker                                                  | #
# | Job Request Module                                                  | #
# |=====================================================================| #
# | Part of the Planetary project: http://trac.mathweb.org/planetary    | #
# |  Research software, produced as part of work done by:               | #
# |  the KWARC group at Jacobs University                               | #
# | Copyright (c) 2012                                                  | #
# | Released under the MIT License (MIT)                                | #
# |---------------------------------------------------------------------| #
# | Adapted from the original NNexus code by                            | #
# |                                  James Gardner and Aaron Krowne     | #
# |---------------------------------------------------------------------| #
# | Deyan Ginev                   #_#     | #
# | http://kwarc.info/people/dginev                            (o o)    | #
# \=========================================================ooo==U==ooo=/ #
package NNexus::Job;
use strict;
use warnings;
use feature qw(say);

use Mojo::DOM;
use NNexus::Discover qw(mine_candidates);
use NNexus::Annotate qw(serialize_concepts);
use NNexus::Classification qw(disambiguate);
use NNexus::Morphology qw(canonicalize_url);

sub new {
  my ($class,%opts) = @_;
  $opts{format} = lc($opts{format}||'html');
  $opts{result} = {};
  $opts{url} = canonicalize_url($opts{url}) if $opts{url};
  bless \%opts, $class; }

sub execute {
  my ($self) = @_;
  my $function = $self->{function};
  if ($function eq 'linkentry') {$self->_link_entry;}
  elsif ($function eq 'indexentry') {$self->_index_entry;}
  else {$self->_fail_with("Invalid action, aborting!"); } }

sub _fail_with {
  my ($self,$message)=@_;
  # TODO: Spec this out, maybe similar to LaTeXML?
  my $result = {payload=>q{},message=>$message,status=>'Failed!'};
  $self->{result} = $result; }

sub _ok_with {
  my ($self,$payload,$message)=@_;
  # TODO: Spec this out, maybe similar to LaTeXML?
  my $result = {payload=>$payload,message=>$message,status=>'OK'};
  $self->{result} = $result; }

sub response { $_[0]->{result};}
sub result { $_[0]->{result}->{payload}; }
sub message { $_[0]->{result}->{message}; }
sub status { $_[0]->{result}->{status}; }

sub _link_entry {
  my ($self) = @_;
  # Process in 2 Steps:
  # I. Concept Discovery
  my ($concepts_mined,$text_length) =
    NNexus::Discover::mine_candidates(
      db=>$self->{db},
      body=>$self->{body},
      url=>$self->{url},
      domain=>$self->{domain},
      format=>$self->{format},
      verbosity=>$self->{verbosity});
  # II. Disambiguation
  my $concepts_refined = NNexus::Classification::disambiguate(
    $concepts_mined,
    text_length=>$text_length,
    include_all=>$self->{include_all},
    verbosity=>$self->{verbosity});
  # III. Annotation
  $self->{annotation} //= 'html';
  $self->{embed} //= 1;
  my $serialized_result =
    NNexus::Annotate::serialize_concepts(
      body=>$self->{body},
      concepts=>$concepts_refined,
      annotation=>$self->{annotation},
      embed=>$self->{embed},
      domain=>$self->{domain},
      verbosity=>$self->{verbosity});
  $self->{result}={payload=>$serialized_result,message=>'No obvious problems.', status=>'OK'};
  $serialized_result; }

sub _index_entry {
  my ($self)=@_;
  my $domain = $self->{domain} || 'all';
  my $url = $self->{url}||$self->{body};
  my $dom = $self->{dom};
  if ($dom && (! ref $dom)) { # Text:
    $dom = Mojo::DOM->new($dom);
  }
  my $should_update = $self->{should_update} // 1;
  require NNexus::Index::Dispatcher;
  my $dispatcher = NNexus::Index::Dispatcher->new(db=>$self->{db},domain=>$domain,
    verbosity=>$self->{verbosity},should_update=>$should_update,
    start=>$url,dom=>$dom);
  my @invalidation_suggestions;
  while (my $payload = $dispatcher->index_step) {
    push @invalidation_suggestions, @{$payload}; }
  my $report_url = ($url ne 'default') ? "http://$url" : 'the default domain root';
  $self->_ok_with(\@invalidation_suggestions,"IndexConcepts succeeded in domain $domain, on $report_url"); }

1;

__END__