File Coverage

blib/lib/NG.pm

Criterion	Covered	Total	%
statement	19	21	90.4
branch			n/a
condition			n/a
subroutine	7	7	100.0
pod			n/a
total	26	28	92.8

package NG;
use strict;
use warnings;
use Try::Tiny;
use autodie;
use YAML::XS ();
use JSON::XS ();
use XML::Simple;
use Spreadsheet::ParseExcel;
use NG::Autobox;
use NG::Array;
use NG::DB;
use NG::Excel;
use NG::Excel::Cell;
use NG::Excel::Sheet;
use NG::HTTP::Client;
use NG::EMail;
use NG::File;
use NG::Dir;
use NG::Log;
use NG::System;
use NG::Time;
use NG::Class;

use base 'Exporter';
our @EXPORT = qw(
  local_run
  remote_run
  fork_run
  taskset

  web_get

  mail_send
  mail_get

  from_json
  from_yaml
  mkdir_p
  rm_r
  cp_r
  read_file
  read_dir
  file_stat

  process_log
  geo_ip

  db
  now

  parse_excel

  def_class
);
our $VERSION = '0.001_05';

sub file_stat   { NG::File->fstat(@_) }
sub file_md5    { NG::File->md5(@_) }
sub cp_r        { NG::File->copy(@_) }
sub process_log { NG::Log::process_log(@_) }
sub geo_ip      { NG::Log::geo_ip(@_) }
sub def_class   { NG::Class::def(@_) }
sub db          { NG::DB->new(@_) }
sub now         { NG::Time->now }
sub local_run   { NG::System::local_run(@_) }
sub remote_run  { NG::System::remote_run(@_) }
sub fork_run    { NG::System::fork_run(@_) }
sub taskset     { NG::System::taskset(@_) }
sub web_get     { NG::HTTP::Client::web_get(@_) }
sub mail_send   { NG::EMail::send(@_) }
sub mail_get    { NG::EMail::get(@_) }
sub mkdir_p     { NG::Dir->make(@_) }
sub rm_r        { NG::Dir->remove(@_) }
sub read_dir    { NG::Dir->read(@_) }

sub read_file {
    my ( $file, $cb ) = @_;
    unless ( defined $cb ) {
        open my $fh, '<', $file;
        return do { local $/; <$fh> }
    }
    my $content = NG::File->read($file);
    $cb->($content);
}

sub from_yaml {
    my $ref = YAML::XS::LoadFile(@_);
    return ref($ref) eq 'HASH'
      ? NG::Hashtable->new($ref)
      : NG::Array->new($ref);
}

sub from_json {
    my $data = &read_file(@_);
    my $ref  = JSON::XS::decode_json($data);
    return ref($ref) eq 'HASH'
      ? NG::Hashtable->new($ref)
      : NG::Array->new($ref);
}

sub from_xml {
    my $data = &read_file(@_);
    my $ref  = XMLin($data);
    return ref($ref) eq 'HASH'
      ? NG::Hashtable->new($ref)
      : NG::Array->new($ref);
}

sub parse_excel {
    my ( $filepath, $cb ) = @_;
    my $parser   = Spreadsheet::ParseExcel->new();
    my $workbook = $parser->parse($filepath);
    if ( !defined $workbook ) {
        die $parser->error() . "\n";
    }
    my $ng_sheet_arr = NG::Array->new;
    for my $sheet ( $workbook->worksheets() ) {
        my ( $row_min, $row_max ) = $sheet->row_range();
        my ( $col_min, $col_max ) = $sheet->col_range();

        my $ng_sheet = NG::Excel::Sheet->new(
            name      => $sheet->get_name(),
            row_count => $row_max + 1,
            col_count => $col_max + 1,
        );

        for my $row ( $row_min .. $row_max ) {
            for my $col ( $col_min .. $col_max ) {
                my $cell = $sheet->get_cell( $row, $col );
                next unless $cell;

                my $ng_cell = NG::Excel::Cell->new( value => $cell->value(), );
                $ng_sheet->{cells}->[$row][$col] = $ng_cell;
            }
        }
        $ng_sheet_arr->push($ng_sheet);
    }

    my $ng_excel = NG::Excel->new($ng_sheet_arr);
    if ( defined $cb ) {
        $cb->($ng_excel);
        $ng_excel->save($filepath);
    }
    else {
        return $ng_excel;
    }
}

sub import {
    my $class = shift;
    strict->import;
    warnings->import;
    utf8->import;
    feature->import(':5.10');
    Try::Tiny->import;
    NG::Autobox::import($class);
    $class->export_to_level( 1, $class, @EXPORT );
}

1;

__END__