File Coverage

lib/MouseX/AttributeHelpers/String.pm

Criterion	Covered	Total	%
statement	17	17	100.0
branch	1	2	50.0
condition	1	2	50.0
subroutine	13	13	100.0
pod	2	2	100.0
total	34	36	94.4

package MouseX::AttributeHelpers::String;
use Mouse;

extends 'MouseX::AttributeHelpers::Base';

has '+method_constructors' => (
    default => sub {
        return +{
            append => sub {
                my (undef, $name) = @_;
                return sub { $_[0]->{$name} .= $_[1] };
            },
            prepend => sub {
                my (undef, $name) = @_;
                return sub { $_[0]->{$name} = $_[1] . $_[0]->{$name} };
            },
            replace => sub {
                my (undef, $name) = @_;
                return sub {
                    (ref $_[2] || '') eq 'CODE'
                        ? $_[0]->{$name} =~ s/$_[1]/$_[2]->()/e
                        : $_[0]->{$name} =~ s/$_[1]/$_[2]/;
                };
            },
            match => sub {
                my (undef, $name) = @_;
                return sub { $_[0]->{$name} =~ $_[1] };
            },
            chop => sub {
                my (undef, $name) = @_;
                return sub { chop $_[0]->{$name} };
            },
            chomp => sub {
                my (undef, $name) = @_;
                return sub { chomp $_[0]->{$name} };
            },
            inc => sub {
                my (undef, $name) = @_;
                return sub { $_[0]->{$name}++ };
            },
            clear => sub {
                my (undef, $name) = @_;
                return sub { $_[0]->{$name} = '' };
            },
        };
    },
);

sub helper_type    { 'Str' }
sub helper_default { '' }

no Mouse;
__PACKAGE__->meta->make_immutable(inline_constructor => 0);
__END__