File Coverage

blib/lib/MooseX/Event.pm

Criterion	Covered	Total	%
statement	29	33	87.8
branch	2	6	33.3
condition			n/a
subroutine	8	9	88.8
pod	1	1	100.0
total	40	49	81.6

# ABSTRACT: A Node style event Role for Moose
package MooseX::Event;
{
  $MooseX::Event::VERSION = '0.3.0_2';
}
use Any::Moose ();
use Any::Moose '::Exporter';

use constant ROLE_CLASS => 'MooseX::Event::Role';

{
    my($import,$unimport,$init_meta) = any_moose('::Exporter')->build_import_methods(
        as_is => [qw( has_event has_events )],
        also => any_moose(),
        );

    sub import {
        my $class = shift;

        my $with_args = {};

        my @args;
        while (local $_ = shift @_) {
            if ( $_ eq '-alias' ) {
                $with_args->{'-alias'} = shift;
            }
            elsif ( $_ eq '-excludes' ) {
                $with_args->{'-excludes'} = shift;
            }
            else {
                push @args, $_;
            }
        }

        my $caller = caller();
        $class->$import( { into => $caller }, @args );

        # I would expect that 'base_class_roles' in setup_import_methods would
        # do the below, but no, it doesn't.
        if ( ! any_moose('::Util')->can('does_role')->( $caller, ROLE_CLASS ) ) {
             eval q{ require }.ROLE_CLASS;
             ROLE_CLASS->meta->apply( $caller->meta, %{$with_args} );
        }
    }

    sub unimport { goto $unimport; }
    *init_meta = $init_meta if defined $init_meta;
}



my %meta;
sub has_event {
    my $class = caller();
    for (@_) {
        $class->meta->add_attribute(
            "event:$_",
            init_arg => undef,
            is => 'ro',
            lazy => 1,
            default => sub {
                require MooseX::Event::Meta;
                MooseX::Event::Meta->new(object=>shift);
            },
            );
    }
}

BEGIN { *has_events = \&has_event }

no Any::Moose '::Exporter';


1;


__END__