File Coverage

blib/lib/MooseX/CoverableModifiers.pm

Criterion	Covered	Total	%
statement	32	32	100.0
branch	5	8	62.5
condition	1	3	33.3
subroutine	7	7	100.0
pod	0	2	0.0
total	45	52	86.5

package MooseX::CoverableModifiers;

use strict;
BEGIN {
    if ($INC{'Devel/Cover.pm'}) {
        require Devel::Declare;
    }
}

use 5.008_001;
our $VERSION = '0.30';

our ($Declarator, $Offset);

sub skip_declarator {
    $Offset += Devel::Declare::toke_move_past_token($Offset);
}

sub gen_parser {
    my $caller = shift;
    my $cnt = 0;
    sub {
        local ($Declarator, $Offset) = @_;
        my $start = $Offset;
        skip_declarator;
        my $pos = $Offset;
        my $linestr = Devel::Declare::get_linestr();
        while (my $char = substr($linestr, $pos, 1))  {
            return if $char eq '{' || $char eq '&';
            if (substr($linestr, $pos, 2) eq '=>') {
                last;
            }
            ++$pos;
        }
        my ($name) = substr($linestr, $Offset, $pos - $Offset) =~ m/(\w+)/;
        my $modifier_name = "__${Declarator}_${name}_${cnt}";
        substr($linestr, $pos, 2) =
            "=> *$modifier_name =";
        Devel::Declare::set_linestr($linestr);
        ++$cnt;
    }
}

sub import {
    my $class = shift;
    my $caller = caller;

    return unless $INC{'Devel/Cover.pm'};
    Devel::Declare->setup_for(
        $caller,
        { map { $_  => { const => gen_parser($caller) } }
              qw(before around after) }
    );
}

1;
__END__