File Coverage

blib/lib/MooX/Cmd/ChainedOptions.pm

Criterion	Covered	Total	%
statement	35	35	100.0
branch	7	8	87.5
condition	2	2	100.0
subroutine	9	9	100.0
pod			n/a
total	53	54	98.1

# --8<--8<--8<--8<--
#
# Copyright (C) 2015 Smithsonian Astrophysical Observatory
#
# This file is part of MooX-Cmd-ChainedOptions
#
# MooX-Cmd-ChainedOptions is free software: you can redistribute it
# and/or modify it under the terms of the GNU General Public License
# as published by the Free Software Foundation, either version 3 of
# the License, or (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see .
#
# -->8-->8-->8-->8--

package MooX::Cmd::ChainedOptions;

use strict;
use warnings;

our $VERSION = '0.03_02';

use Import::Into;
use Moo::Role     ();
use MooX::Options ();

use MooX::Cmd::ChainedOptions::Role ();
use List::Util qw/ first /;

my %ROLE;

sub import {

    my $class  = shift;
    my $target = caller;

    unless ( $target->DOES( 'MooX::Cmd::Role' ) ) {
        require Carp;
        Carp::croak( "$target must use MooX::Cmd prior to using ",
            __PACKAGE__, "\n" );
    }

    # don't do this twice
    return if $ROLE{$target};

    # load MooX::Options into target class.
    MooX::Options->import::into( $target );

    # guess if an app or a command

    # if $target is a cmd, a parent class (app or cmd) must have
    # been loaded.  $target must be a direct descendant of a
    # parent class' command_base.  use the _build_command_base method
    # as it can be used as a class method; command_base is an object method

    my ( $base, $pkg ) = $target =~ /^(.*)?::([^:]+)$/;
    $base ||= '';
    my $parent = first { $base eq $_->_build_command_base } keys %ROLE;

    $ROLE{$target}
      = $parent
      ? MooX::Cmd::ChainedOptions::Role->build_variant( $parent,
        $ROLE{$parent} )
      : __PACKAGE__ . '::Base';

    # need only apply role to commands & subcommands
    Moo::Role->apply_roles_to_package( $target, $ROLE{$target} )
      if $parent;

    return;
}

1;


__END__