File Coverage

lib/Mojolicious/Plugin/TagHelpersI18N.pm

Criterion	Covered	Total	%
statement	68	79	86.0
branch	9	14	64.2
condition	3	7	42.8
subroutine	14	15	93.3
pod	1	1	100.0
total	95	116	81.9

package Mojolicious::Plugin::TagHelpersI18N;

# ABSTRACT: TagHelpers with I18N support

use strict;
use warnings;

use Mojolicious::Plugin::TagHelpers;

our $VERSION = 0.03;

use Mojo::Collection;
use Mojo::Util qw(deprecated xml_escape);
use Scalar::Util 'blessed';
use Unicode::Collate;

use Data::Dumper;

use parent 'Mojolicious::Plugin';

sub register {
    my ($self, $app, $config) = @_;

    my $collate = Unicode::Collate->new;
    $app->helper( select_field => sub {
        _select_field(@_, collate => $collate )
    } );

    $config ||= {};
    $app->attr(
        translation_method => $config->{method} || 'l'
    );
}

sub _prepare {
    my ($self, $options, %attr) = @_;

    my %translated;
    my $index = 0;
    for my $option ( @{$options} ) {
        if (ref $option eq 'HASH') {
            deprecated
                'hash references are DEPRECATED in favor of Mojo::Collection objects';
            $option = Mojo::Collection->new(each %$option);
        }

        $option = [$option => $option] unless ref $option eq 'ARRAY';

        if ( !$attr{no_translation} ) {
            my $method   = $self->app->translation_method;
            $option->[0] = $self->$method( $option->[0] );
        }

        push @{ $translated{ $option->[0] } }, $index;

        $index++;
    }

    if ( $attr{sort} ) {
        my @sorted = $attr{collate}->sort( keys %translated );
        my @sorted_options = map{ @{$options}[ @{ $translated{$_} } ] }@sorted;

        return \@sorted_options;
    }

    return $options;
}

sub _select_field {
    my ($self, $name, $options, %attrs) = (shift, shift, shift, @_);

    my %values = map { $_ => 1 } @{ $self->every_param($name) || [] };

    my %opts;
    my @fields = qw(no_translation sort collate);
    @opts{@fields} = delete @attrs{@fields};

    $options = _prepare( $self, $options, %opts );

    my $groups = '';
    for my $group (@$options) {

        # DEPRECATED in Top Hat!
        if (ref $group eq 'HASH') {
            deprecated
                'hash references are DEPRECATED in favor of Mojo::Collection objects';
            $group = Mojo::Collection->new(each %$group);
        }

        # "optgroup" tag
        if (blessed $group && $group->isa('Mojo::Collection')) {
            my ($label, $values) = splice @$group, 0, 2;
            my $prepared = _prepare( $self, $values, %opts );
            my $content = join '', map { Mojolicious::Plugin::TagHelpers::_option(\%values, $_) } @$prepared;
            $groups .= Mojolicious::Plugin::TagHelpers::_tag('optgroup', label => $label, @$group, sub {$content});
        }

        # "option" tag
        else { $groups .= Mojolicious::Plugin::TagHelpers::_option(\%values, $group) }
    }

    return Mojolicious::Plugin::TagHelpers::_validation(
        $self, $name, 'select', %attrs, name => $name, sub {$groups},
    );
}

1;

__END__