File Coverage

lib/Mojolicious/Plugin/Subdispatch.pm

Criterion	Covered	Total	%
statement	29	29	100.0
branch	12	14	85.7
condition	3	3	100.0
subroutine	7	7	100.0
pod	1	1	100.0
total	52	54	96.3

package Mojolicious::Plugin::Subdispatch;
use Mojo::Base 'Mojolicious::Plugin';

use Mojo::UserAgent::Transactor;

our $VERSION = '0.04';

has app         => sub { die 'not registered!' };
has transactor  => sub { Mojo::UserAgent::Transactor->new };
has 'base_url';

sub _subdispatch {
    my ($self, $method, @args) = @_;

    # extract post data
    my $post_data = (uc $method eq 'POST' and ref $args[-1] eq 'HASH') ?
        pop @args : undef;

    # build request url
    my $url = $self->app->url_for(@args);
    $url->base($self->base_url) if defined $self->base_url;

    # build transaction
    my $tx = $post_data ?
        $self->transactor->tx($method => $url => form => $post_data)
        : $self->transactor->tx($method => $url);

    # dispatch
    $self->app->handler($tx);

    return $tx;
}

# Mojo::UserAgent like interface
# we don't really need post_form, but Mojo::UA uses it.
{
    no strict 'refs';
    for my $name (qw(DELETE GET HEAD POST POST_FORM PUT)) {
        *{__PACKAGE__ . '::' . lc($name)} = sub {
            my $self = shift;
            my $method = $name eq 'POST_FORM' ? 'POST' : $name;
            return $self->_subdispatch($method => @_)->res;
        };
    }
}

sub register {
    my ($self, $app, $conf) = @_;
    $self->app($app);

    # does your base are belong to us?
    if (defined $conf->{base_url}) {
        my $base_url = $conf->{base_url};
        $base_url = Mojo::URL->new($base_url) unless ref $base_url;
        $self->base_url($base_url);
    }

    # add subdispatch helper
    $app->helper(subdispatch => sub {
        my $s = shift;

        # Mojo::UserAgent like interface usage
        return $self unless @_;

        # direct subdispatch call
        return $self->_subdispatch(@_);
    });
}

1;
__END__