File Coverage

blib/lib/Mojo/MemoryMap/Writer.pm

Criterion	Covered	Total	%
statement	32	32	100.0
branch	4	6	66.6
condition			n/a
subroutine	8	8	100.0
pod	4	4	100.0
total	48	50	96.0

package Mojo::MemoryMap::Writer;
use Mojo::Base -base;

use Fcntl qw(:flock);
use Sereal qw(decode_sereal encode_sereal);

sub DESTROY { flock(shift->{fh}, LOCK_UN) or die "Couldn't flock: $!" }

sub change {
  my ($self, $cb) = @_;
  my $data = $self->fetch;
  $cb->($_) for $data;
  return $self->store($data);
}

sub fetch {
  my $self = shift;
  my $len  = unpack 'N', substr(${$self->{map}}, 0, 4);
  return decode_sereal(substr(${$self->{map}}, 4, $len));
}

sub new {
  my $self = shift->SUPER::new(@_);
  flock($self->{fh}, LOCK_EX) or die "Couldn't flock: $!";
  return $self;
}

sub store {
  my ($self, $data) = @_;

  my $bin   = encode_sereal($data);
  my $bytes = pack('N', length $bin) . $bin;

  ${$self->{usage}} = my $usage = length $bytes;
  return undef if $usage > length ${$self->{map}};
  substr ${$self->{map}}, 0, $usage, $bytes;

  return 1;
}

1;

=encoding utf8

=head1 NAME

Mojo::MemoryMap::Writer - Writer

=head1 SYNOPSIS

  use Mojo::MemoryMap::Writer;

  my $writer = Mojo::MemoryMap::Writer->new(map => $map);
  $writer->store({foo => 123});
  say $writer->fetch->{foo};

=head1 DESCRIPTION

L is a scope guard for L that allows you to write safely to anonymous mapped
memory segments.

=head1 METHODS

L inherits all methods from L and implements the following new ones.

=head2 change

  my $bool = $writer->change(sub {...});

Fetch data, modify it in the closure and store it again right away.

  # Remove a value safely
  $writer->change(sub { delete $_->{foo} });

=head2 fetch

  my $data = $writer->fetch;

Fetch data.

=head2 new

  my $writer = Mojo::MemoryMap::Writer->new;
  my $writer = Mojo::MemoryMap::Writer->new(map => $map);
  my $writer = Mojo::MemoryMap::Writer->new({map => $map});

Construct a new L object.

=head2 store

  my $bool = $writer->store({foo => 123});

Store data, replacing all existing data.

=head1 SEE ALSO

L, L, L.

=cut