File Coverage

blib/lib/Mojolicious/Plugin/Statsd.pm

Criterion	Covered	Total	%
statement	36	41	87.8
branch	8	10	80.0
condition	6	7	85.7
subroutine	12	14	85.7
pod	8	8	100.0
total	70	80	87.5

package Mojolicious::Plugin::Statsd;
$Mojolicious::Plugin::Statsd::VERSION = '0.04';
use Mojo::Base 'Mojolicious::Plugin';

use Mojo::Loader;
use Time::HiRes qw(gettimeofday tv_interval);

has adapter => undef;
has prefix  => '';

sub register {
  my ($self, $app, $conf) = @_;

  $self->_load_adapter(($conf->{adapter} // 'Statsd'), $conf);

  $self->{prefix} = $conf->{prefix} // $app->moniker . q[.];

  $app->helper(($conf->{helper} // 'stats') => sub {$self});
}

sub _load_adapter {
  my ($self, $adapter, $conf) = @_;

  return $self->adapter($adapter) if ref $adapter;

  my $class = sprintf('%s::Adapter::%s', ref $self, $adapter);
  my $err   = Mojo::Loader::load_class $class;

  if (ref $err) {
    die "Loading adapter $class failed: $err";
  }

  $self->adapter($class->new(%$conf));
}

sub with_prefix {
  my ($self, $add_prefix) = @_;

  (ref $self)->new(%$self, prefix => $self->prefix . $add_prefix);
}

sub counter {
  my ($self, $name, @args) = @_;

  $self->adapter->counter($self->_prepare_names($name), @args);
}

sub increment {
  (shift)->counter(shift, 1, shift);
}

sub decrement {
  (shift)->counter(shift, -1, shift);
}

sub timing {
  my ($self, $name, @args) = @_;

  my ($time, $sample_rate) = ref $args[1] ? reverse(@args) : @args;

  if (ref $time eq 'CODE') {
    my @start = gettimeofday();
    $time->();
    $time = int(tv_interval(\@start) * 1000);
  }

  $self->adapter->timing($self->_prepare_names($name), $time, $sample_rate);
}

sub gauge {
  my ($self, $name, $value) = @_;

  $self->adapter->gauge($self->_prepare_names($name), $value);
}

sub set_add {
  my ($self, $name, @values) = @_;

  $self->adapter->set_add($self->_prepare_names($name), @values);
}

sub _prepare_names {
  my ($self, $names) = @_;

  return [map { $self->prefix . $_ } ref($names) ? @$names : $names];
}

1;
__END__