File Coverage

blib/lib/Mojolicious/Plugin/Statsd/Adapter/Statsd.pm

Criterion	Covered	Total	%
statement	29	30	96.6
branch	8	12	66.6
condition	4	6	66.6
subroutine	8	8	100.0
pod	4	4	100.0
total	53	60	88.3

package Mojolicious::Plugin::Statsd::Adapter::Statsd;
$Mojolicious::Plugin::Statsd::Adapter::Statsd::VERSION = '0.03';
use Mojo::Base -base;

use IO::Socket::INET ();

has socket => sub {
  my $self = shift;

  IO::Socket::INET->new(
    Proto    => 'udp',
    PeerAddr => $self->addr,
    Blocking => 0,
  ) or die "Can't open write socket for stats: $@";
};

has addr => sub {
  $ENV{STATSD_ADDR} // '127.0.0.1:8125';
};

sub timing {
  my ($self, $names, $time, $sample_rate) = @_;

  if (($sample_rate //= 1) < 1) {
    return unless rand() <= $sample_rate;
  }

  $self->_send(
    map { _sampled($_, $sample_rate) }
    map { sprintf '%s:%d|ms', $_, $time }
    @$names
  );
}

sub counter {
  my ($self, $counters, $delta, $sample_rate) = @_;

  if (($sample_rate //= 1) < 1) {
    return unless rand() <= $sample_rate;
  }

  $self->_send(
     map { _sampled($_, $sample_rate) }
     map { sprintf '%s:%d|c', $_, $delta }
     @$counters
  );
}

sub gauge {
  my ($self, $gauges, $value) = @_;

  $self->_send(
    map { sprintf '%s:%s|g', $_, $value }
    @$gauges
  );
}

sub set_add {
  my ($self, $sets, @values) = @_;

  $self->_send(
    map {
      my $set = $_;
      map { sprintf '%s:%s|s', $set, $_ } @values
    } @$sets
  );
}

sub _sampled { $_[1] == 1 ? $_[0] : ($_[0] . '|@' . $_[1]) }

sub _send {
  my ($self) = shift;
  my $payload = join("\012", @_);

  ($self->socket->send($payload) // -1) == length($payload)
    or warn "stats: UDP packet may have been truncated ($!)";
}

1;
__END__