File Coverage

lib/Mojolicious/Plugin/SessionCompress.pm

Criterion	Covered	Total	%
statement	42	42	100.0
branch	10	10	100.0
condition	7	11	63.6
subroutine	9	9	100.0
pod	1	1	100.0
total	69	73	94.5

package Mojolicious::Plugin::SessionCompress;
use Mojo::Base 'Mojolicious::Plugin';
use Mojo::Util ();
use Mojo::JSON ();
use Compress::Zlib ();

our $VERSION = '0.03';

sub register {
  my ($self, $app, $conf) = @_;
  $conf ||= {};
  my ($compress, $decompress, $serialize, $deserialize);

  my $min_size = exists $conf->{min_size} ? delete $conf->{min_size} : 250;
  if (exists $conf->{compress} && exists $conf->{decompress}) {
    $compress = delete $conf->{compress};
    $decompress = delete $conf->{decompress};
  } else {
    $compress = sub {
      my $string = shift;

      my $d = Compress::Zlib::deflateInit(-Level => 1, -memLevel => 5, -WindowBits => -15);
      return $d->deflate($string) . $d->flush;
    };

    $decompress = sub {
      my $string = $_[0];

      my $d = Compress::Zlib::inflateInit(-WindowBits => -15);
      my ($inflated, $status) = $d->inflate($string);
      # Check to see if it's actually compressed
      return $_[0] if $status != Compress::Zlib::Z_STREAM_END || length($inflated) <= 1;
      return $inflated;
    };
  }

  if (exists $conf->{serialize} && exists $conf->{deserialize}) {
    $serialize = delete $conf->{serialize};
    $deserialize = delete $conf->{deserialize};
  } else {
    $serialize = \&Mojo::JSON::encode_json;
    $deserialize = \&Mojo::JSON::j;
  }

  $app->sessions->serialize(sub {
    my $hashref = shift;

    my $serialized = $serialize->($hashref);
    return $serialized if (length $serialized < $min_size);
    return $compress->($serialized);
  });

  $app->sessions->deserialize(sub {
    my $string = shift;

    return $deserialize->($decompress->($string));
  });
}

1;
__END__