File Coverage

lib/Mojolicious/Plugin/RelativeUrlFor.pm

Criterion	Covered	Total	%
statement	42	43	97.6
branch	10	16	62.5
condition	7	9	77.7
subroutine	6	6	100.0
pod	1	2	50.0
total	66	76	86.8

package Mojolicious::Plugin::RelativeUrlFor;
use Mojo::Base 'Mojolicious::Plugin';

our $VERSION = '0.051';

# function version of the deleted Mojo::URL::to_rel method
# from Mojolicious repository revision 551a31
sub url_to_rel {
    my $self = shift;

    my $rel = $self->clone;
    return $rel unless $rel->is_abs;

    # Scheme and authority
    my $base = shift || $rel->base;
    $rel->base($base)->scheme(undef);
    $rel->userinfo(undef)->host(undef)->port(undef) if $base->authority;

    # Path
    my @parts       = @{$rel->path->parts};
    my $base_path   = $base->path;
    my @base_parts  = @{$base_path->parts};
    pop @base_parts unless $base_path->trailing_slash;
    while (@parts && @base_parts && $parts[0] eq $base_parts[0]) {
        shift @$_ for \@parts, \@base_parts;
    }
    my $path = $rel->path(Mojo::Path->new)->path;
    $path->leading_slash(1) if $rel->authority;
    $path->parts([('..') x @base_parts, @parts]);
    $path->trailing_slash(1) if $self->path->trailing_slash;

    return $rel;
}

sub register {
    my ($self, $app, $conf) = @_;

    # url_for helper backup
    my $url_for = *Mojolicious::Controller::url_for{CODE};

    # helper sub ref
    my $rel_url_for = sub {
        my $c = shift;

        # create urls
        my $url     = $url_for->($c, @_)->to_abs;
        my $req_url = $c->req->url->to_abs;

        # return relative version if request url exists
        if ($req_url->to_string) {

            # repair if empty
            my $rel_url = url_to_rel($url, $req_url);
            return Mojo::URL->new('./') unless $rel_url->to_string;
            return $rel_url;
        }

        # change nothing without request url
        return $url;
    };

    # register rel(ative)_url_for helpers
    $app->helper(relative_url_for   => $rel_url_for);
    $app->helper(rel_url_for        => $rel_url_for);

    # replace url_for helper
    if ($conf->{replace_url_for}) {
        no strict 'refs';
        no warnings 'redefine';
        *Mojolicious::Controller::url_for = $rel_url_for;
    }
}

1;
__END__