File Coverage

blib/lib/Mojolicious/Plugin/ParamExpand.pm

Criterion	Covered	Total	%
statement	30	31	96.7
branch	5	6	83.3
condition			n/a
subroutine	7	7	100.0
pod	1	1	100.0
total	43	45	95.5

package Mojolicious::Plugin::ParamExpand;

use Mojo::Base 'Mojolicious::Plugin';
use CGI::Expand;

our $VERSION = '0.03';

sub register
{
  my ($self, $app, $config) = @_;
  my $class = 'Mojolicious::Plugin::ParamExpand::expander';

  _make_package($class, $config);

  $app->hook(before_dispatch => sub {
      my $c = shift;
      my $hash;

      eval { $hash = $class->expand_hash($c->req->params->to_hash) };
      if($@) {
	  # Mojolicious < 6.0 uses render_exception
	  if($c->can('render_exception')) {
	    $c->render_exception($@);
	  }
	  else {
	    $c->reply->exception($@);
	  }

	  return;
      }

      $c->param($_ => $hash->{$_}) for keys %$hash;
  });
}

sub _make_package
{
    no strict 'refs';

    my ($class, $config) = @_;
    @{"${class}::ISA"} = 'CGI::Expand';

    for(qw|max_array separator|) {
        my $val = $config->{$_};
        *{"${class}::$_"} = sub { $val } if defined $val;
    }
}

1;

__END__