File Coverage

blib/lib/Mojolicious/Plugin/PPI.pm

Criterion	Covered	Total	%
statement	16	18	88.8
branch			n/a
condition			n/a
subroutine	6	6	100.0
pod			n/a
total	22	24	91.6

package Mojolicious::Plugin::PPI;

use Mojo::Base 'Mojolicious::Plugin';

use Mojo::Util;
use Mojo::ByteStream 'b';

use File::Basename ();
use File::Spec;

use PPI::HTML;

our $VERSION = '0.07';
$VERSION = eval $VERSION;

has 'line_numbers'  => 1;
has 'no_check_file' => 0;
has 'ppi_html_on'  => sub { PPI::HTML->new( line_numbers => 1 ) };
has 'ppi_html_off' => sub { PPI::HTML->new( line_numbers => 0 ) };
has 'src_folder';

has style => <<'END';
.ppi-code {
  display: inline-block;
  min-width: 400px;
  background-color: #F8F8F8;
  border-radius: 10px;
  padding: 15px;
}
END

has class_style => sub {{
  line_number_on   => { display => 'inline' },
  line_number_off  => { display => 'none'   },

  cast => '#339999',
  comment => '#008080',
  core => '#FF0000',
  double => '#999999',
  heredoc_content => '#FF0000',
  interpolate => '#999999',
  keyword => '#BD2E2A',
  line_number => '#666666',
  literal => '#999999',
  magic => '#0099FF',
  match => '#9900FF',
  number => '#990000',
  operator => '#DD7700',
  pod => '#008080',
  pragma => '#A33AF7',
  regex => '#9900FF',
  single => '#FF33FF',
  substitute => '#9900FF',
  symbol => '#389A7D',
  transliterate => '#9900FF',
  word => '#999999',
}};

sub register {
  my ($plugin, $app) = (shift, shift);
  $plugin->initialize($app, @_);

  push @{$app->static->classes},   __PACKAGE__;
  push @{$app->renderer->classes}, __PACKAGE__;

  $app->helper( ppi => sub {
    return $plugin if @_ == 1;
    return $plugin->convert(@_);
  });
  $app->helper( ppi_css => sub { $_[0]->ppi->generate_css(@_) } );
}

sub initialize {
  my ($plugin, $app) = (shift, shift);
  my %opts = @_ == 1 ? %{$_[0]} : @_;
  my @unknown;
  foreach my $key (keys %opts) {
    my $code = $plugin->can($key);
    unless ($code) {
      push @unknown, $key;
      next;
    }
    $plugin->$code($opts{$key});
  }

  if ( @unknown ) {
    warn "Unknown option(s): " . join(", ", @unknown) . "\n";
  }
}

sub convert {
  my $plugin = shift;
  my $c = shift;

  my %opts = $plugin->process_converter_opts(@_);

  my $converter =
    $opts{line_numbers}
    ? $plugin->ppi_html_on
    : $plugin->ppi_html_off;

  my $id = $plugin->generate_id($c);

  my @tag = (
    $opts{inline} ? 'code' : 'pre',
    id    => $id,
    class => 'ppi-code ' . ($opts{inline} ? 'ppi-inline' : 'ppi-block'),
  );

  if ($opts{line_numbers}) {
    push @tag, ondblclick => "ppi_toggleLineNumbers('$id')";
    $c->stash('ppi.js.required' => 1);
  }

  my %render_opts = (
    'ppi.code' => $converter->html( $opts{file} ? $opts{file} : \$opts{string} ),
    'ppi.tag'  => \@tag,
  );

  #TODO use render_to_string once Mojo 5.00 is required
  return $c->include('ppi_template', %render_opts);
}

sub generate_id {
  my ($plugin, $c) = @_;
  return 'ppi' . $c->stash->{'ppi.id'}++;
}

sub check_file {
  my ($self, $file) = @_;
  return undef if $self->no_check_file;

  if ( my $folder = $self->src_folder ) {
    die "Could not find folder $folder\n" unless -d $folder;
    $file = File::Spec->catfile( $folder, $file );
  }

  return -e $file ? $file : undef;
}

sub process_converter_opts {
  my $plugin = shift;

  my $string = do {
    no warnings 'uninitialized';
    if (ref $_[-1] eq 'CODE') {
      Mojo::Util::trim pop->();
    }
  };

  my %opts;
  if (ref $_[-1]) {
    %opts = %{ pop() };
  }

  if ( @_ % 2 ) {
    die "Cannot specify both a string and a block\n" if $string;

    $string = shift;
    $opts{file} = $plugin->check_file($string);
    unless ( $opts{file} ) {
      $opts{inline} //= 1;
    }

  }

  %opts = (%opts, @_) if @_;

  $opts{string} = $string unless defined $opts{file};

  $opts{line_numbers} //= 0 if $opts{inline};
  $opts{line_numbers} //= $plugin->line_numbers;

  return %opts;
}

sub generate_css {
  my ($plugin, $c) = @_;
  my $sheet = b("pre.ppi-code br { display: none; }\n");
  $$sheet .= $plugin->style."\n";
  my $cs = $plugin->class_style;
  foreach my $key (sort keys %$cs) {
    my $value = $cs->{$key};
    $value = { color => $value } unless ref $value;
    $$sheet .= ".ppi-code .$key { ";
    foreach my $prop ( sort keys %$value ) {
      $$sheet .= "$prop: $value->{$prop}; ";
    }
    $$sheet .= "}\n";
  }
  return $c->stylesheet(sub{$sheet});
}

1;

__DATA__