File Coverage

lib/Mojolicious/Plugin/MoreHTMLHelpers.pm

Criterion	Covered	Total	%
statement	34	34	100.0
branch	10	10	100.0
condition	4	4	100.0
subroutine	7	7	100.0
pod	1	1	100.0
total	56	56	100.0

package Mojolicious::Plugin::MoreHTMLHelpers;

# ABSTRACT: Some general helpers

use strict;
use warnings;

use Mojo::Base 'Mojolicious::Plugin';

our $VERSION = 0.02;

sub register {
    my ($self, $app, $config) = @_;

    $app->helper( textcolor => sub {
        my $c = shift;

        my $color = shift // '#000000';

        my ($red, $green, $blue);

        if ( length $color == 7 ) {
            ($red, $green, $blue) = $color =~ m{\#(..)(..)(..)};
        }
        elsif ( length $color == 4 ) {
            ($red, $green, $blue) = $color =~ m{\#(.)(.)(.)};
            for ( $red, $green, $blue ) {
                $_ = $_ x 2;
            }
        }

        my $brightness = _perceived_brightness( $red, $green, $blue );

        return $brightness > 130 ? '#000000' : '#ffffff';
    } );

    $app->helper( gradient => sub {
        my ($c) = shift;

        my $color = shift // '#ffffff';

        return sprintf q~
            background: %s !important;
            background: -moz-linear-gradient(top,  %s 0%%,%s 100%%) !important;
            background: -webkit-gradient(linear, left top, left bottom, color-stop(0%%, %s), color-stop(100%%,%s)) !important;
            background: -webkit-linear-gradient(top,  %s 0%%,%s 100%%) !important;
            background: -o-linear-gradient(top,  %s 0%%,%s 100%%) !important;
            background: -ms-linear-gradient(top,  %s 0%%,%s 100%%) !important;
            background: linear-gradient(to bottom,%s 0%%,%s 100%%) !important;
        ~, ($color) x 13;
    });
}

sub _perceived_brightness {
    my ($red, $green, $blue) = @_;

    if ( grep { !defined $_ || $_ =~ m{[^A-Fa-f0-9]} }($red, $green, $blue) ) {
        return 200;
    }

    $red   = hex $red;
    $green = hex $green;
    $blue  = hex $blue;

    my $brightness = int ( sqrt (
        ( $red   * $red   * .299 ) +
        ( $green * $green * .587 ) +
        ( $blue  * $blue  * .114 )
    ));

    return $brightness;
}

1;

__END__