File Coverage

blib/lib/Mojolicious/Plugin/Model.pm

Criterion	Covered	Total	%
statement	43	49	87.7
branch	14	24	58.3
condition	6	10	60.0
subroutine	10	10	100.0
pod	1	1	100.0
total	74	94	78.7

package Mojolicious::Plugin::Model;
use Mojo::Base 'Mojolicious::Plugin';

use List::Util 'any';
use Mojo::Loader ();
use Mojo::Util 'camelize';

our $VERSION = '0.11';

sub register {
  my ($plugin, $app, $conf) = @_;

  $app->helper(
    model => sub {
      my ($self, $name) = @_;
      $name //= $conf->{default};

      my $model;
      return $model if $model = $plugin->{models}{$name};

      my $class = _load_class_for_name($plugin, $app, $conf, $name)
        or return undef;

      my $params = $conf->{params}{$name};
      $model = $class->new(ref $params eq 'HASH' ? %$params : (), app => $app);
      $plugin->{models}{$name} = $model;
      return $model;
    }
  );

  $app->helper(
    entity => sub {
      my ($self, $name) = @_;
      $name //= $conf->{default};

      my $class = _load_class_for_name($plugin, $app, $conf, $name)
        or return undef;

      my $params = $conf->{params}{$name};
      return $class->new(ref $params eq 'HASH' ? %$params : (), app => $app);
    }
  );

}

sub _load_class {
  my $class = shift;

  my $error = Mojo::Loader->can('new') ? Mojo::Loader->new->load($class) : Mojo::Loader::load_class($class);

  return 1 unless $error;
  die $error if ref $error;
  return;
}

sub _load_class_for_name {
  my ($plugin, $app, $conf, $name) = @_;
  return $plugin->{classes_loaded}{$name} if $plugin->{classes_loaded}{$name};

  my $ns   = $conf->{namespaces}   // [camelize($app->moniker) . '::Model'];
  my $base = $conf->{base_classes} // [qw(MojoX::Model)];

  $name = camelize($name) if $name =~ /^[a-z]/;

  for my $class ( map "${_}::$name", @$ns ) {
    next unless _load_class($class);

    unless ( any { $class->isa($_) } @$base ) {
      $app->log->debug(qq[Class "$class" is not a model]);
      next;
    }
    $plugin->{classes_loaded}{$name} = $class;
    return $class;
  }
  $app->log->debug(qq[Model "$name" does not exist]);
  return undef;
};

1;

__END__