File Coverage

blib/lib/Mojolicious/Plugin/MethodOverride.pm

Criterion	Covered	Total	%
statement	28	28	100.0
branch	14	14	100.0
condition	7	9	77.7
subroutine	6	6	100.0
pod	1	1	100.0
total	56	58	96.5

package Mojolicious::Plugin::MethodOverride;

use 5.010;
use Mojo::Base 'Mojolicious::Plugin';

use Scalar::Util qw(weaken);

our $VERSION = '0.052';

sub register {
    my ($self, $app, $conf) = @_;

    my $header =
        exists $conf->{header} ? $conf->{header} : 'X-HTTP-Method-Override';
    my $param = exists $conf->{param} ? $conf->{param} : undef;

    $app->hook(
        after_build_tx => sub {
            my $tx = shift;

            weaken $tx;

            $tx->req->content->on(body => sub {
                my $req = $tx->req;

                return unless $req->method eq 'POST';

                my $method = defined $header && $req->headers->header($header);

                if ($method) {
                    $req->headers->remove($header);
                }
                elsif (defined $param) {
                    $method = $req->url->query->clone->param($param);
                }

                if ($method and $method =~ /^[A-Za-z]+$/) {
                    $app->log->debug(($header // $param) . ': ' . $method);
                    $req->method($method);
                }
            });
        }
    );

    if (defined $param) {
        $app->hook(before_dispatch => sub {
            shift->req->url->query->remove($param);
        });
    }
}

1;

__END__