File Coverage

lib/Mojolicious/Plugin/JSUrlFor.pm

Criterion	Covered	Total	%
statement	51	52	98.0
branch	6	8	75.0
condition	5	7	71.4
subroutine	10	10	100.0
pod	1	1	100.0
total	73	78	93.5

package Mojolicious::Plugin::JSUrlFor;
use Mojo::Base 'Mojolicious::Plugin';

our $VERSION = '0.16';

use Mojo::ByteStream qw/b/;
use Data::Dumper;
use v5.10;

sub register {
    my ( $self, $app, $config ) = @_;

    if ( $config->{route} ) {
        $app->routes->get( $config->{route} => sub {
            my $c = shift;
            $c->render(
                inline => $c->app->_js_url_for_code_only(),
                format => 'js'
            );
        } )->name('js_url_for');
    }

    $app->helper(
        js_url_for => sub {
            my $c      = shift;
            state $b_js; # bytestream for $js

            if ( $b_js && $app->mode eq 'production' ) {
                return $b_js;
            }

            my $js = $app->_js_url_for_code_only;

            $b_js = b(''.$js.'');
            return $b_js;
        }
    );

    $app->helper(
        _js_url_for_code_only => sub {
            my $c      = shift;
            my $endpoint_routes = $self->_collect_endpoint_routes( $app->routes );

            my %names2paths;
            foreach my $route (@$endpoint_routes) {
                next unless $route->name;

                my $path = $self->_get_path_for_route($route);
                $path =~ s{^/*}{/}g; # TODO remove this quickfix

                $names2paths{$route->name} = $path;
            }

            my $json_routes = $c->render_to_string( json => \%names2paths );
            utf8::decode( $json_routes );

            my $js = <<"JS";
var mojolicious_routes = $json_routes;
function url_for(route_name, captures) {
    var pattern = mojolicious_routes[route_name];
    if(!pattern) return route_name;

    // Fill placeholders with values
    if (!captures) captures = {};
    for (var placeholder in captures) { // TODO order placeholders from longest to shortest
        var re = new RegExp('[:*]' + placeholder, 'g');
        pattern = pattern.replace(re, captures[placeholder]);
    }

    // Clean not replaces placeholders
    pattern = pattern.replace(/[:*][^/.]+/g, '');

    return pattern;
}
JS
            return $js;
        } );
}


sub _collect_endpoint_routes {
    my ( $self, $route ) = @_;
    my @endpoint_routes;

    foreach my $child_route ( @{ $route->children } ) {
        if ( $child_route->is_endpoint ) {
            push @endpoint_routes, $child_route;
        } else {
            push @endpoint_routes, @{ $self->_collect_endpoint_routes($child_route) };
        }
    }
    return \@endpoint_routes
}

sub _get_path_for_route {
    my ( $self, $parent ) = @_;

    my $path = $parent->pattern->pattern // '';

    while ( $parent = $parent->parent ) {
        $path = ($parent->pattern->pattern//'') . $path;
    }

    return $path;
}

1;
__END__