File Coverage

blib/lib/Mojolicious/Plugin/Images/Service.pm

Criterion	Covered	Total	%
statement	93	104	89.4
branch	27	50	54.0
condition	1	3	33.3
subroutine	17	17	100.0
pod	6	6	100.0
total	144	180	80.0

package Mojolicious::Plugin::Images::Service;
use Mojo::Base -base;
use 5.20.0;
use experimental 'signatures';
use IO::All;
use Imager;
use Mojo::URL;
use Mojo::Path;
use Mojolicious::Plugin::Images::Util ':all';
use Mojolicious::Plugin::Images::Transformer;
use Mojo::Util 'camelize';

has [qw(namespace url_prefix ext dir suffix write_options read_options)];
has 'transform';
has 'controller';

sub url($self, $id) {
  my $fname
    = check_id($id) . $self->suffix . ($self->ext ? '.' . $self->ext : '');
  my $fpath = Mojo::Path->new($fname)->leading_slash(0);
  my $url   = Mojo::URL->new($self->url_prefix);
  $url->path($url->path->trailing_slash(1)->merge($fpath)->canonicalize);
  $url;
}

sub canonpath($self, $id) {
  $id = check_id($id);
  my $fname = $id . $self->suffix . ($self->ext ? '.' . $self->ext : '');
  io->catfile(check_dir($self->dir, $self->controller->app), $fname)
    ->canonpath;
}

sub exists ($self, $id) {
  io($self->abs_path($id))->exists;
}

sub read ($self, $id) {
  Imager::->new(
    file => $self->abs_path(check_id($id)),
    %{$self->read_options || {}}
  );
}


sub _trans($self, $id, $img) {
  my $trans = $self->transform;
  my $new;
  my %args = (
    service    => $self,
    id         => $id,
    controller => $self->controller,
    image      => $img,
  );

  if (ref $trans eq 'CODE') {
    plugin_log($self->controller->app, "Transformation to cb with id $id");
    $new = $trans->(Mojolicious::Plugin::Images::Transformer->new(%args));
  }

  elsif (ref $trans eq 'ARRAY') {
    $new = $img;
    my @arr = @$trans;
    while (@arr) {
      my ($act, $args) = (shift @arr, shift @arr);
      $new = $new->$act(%$args);
    }
  }

  elsif ($trans && $trans =~ /^([\w\-:]+)\#([\w]+)$/) {
    my ($class, $action) = (camelize($1), $2);
    $class = $self->namespace . "::$class" if $self->namespace;
    plugin_log($self->controller->app,
      "Transformation to class $class and action $action with id $id");
    $new = $class->new(%args)->$action;
  }

  else {
    $new = $img;
  }
  return $new;
}

sub abs_path($self, $id) {
  my $canonpath = $self->canonpath($id);
  return $canonpath if io($canonpath)->is_absolute;

  return $self->controller->app->home->rel_file($canonpath);
}

sub write($self, $id, $img) {
  my $abs_path = $self->abs_path($id);
  my $dir      = io->file($abs_path)->filepath;
  my $new      = _trans($self, $id, $img);

  io->dir($dir)->mkpath unless io->dir($dir)->exists;
  $new->write(file => $abs_path, %{$self->write_options || {}})
    or die Imager::->errstr;
}

1;

__END__