File Coverage

blib/lib/Mojolicious/Plugin/Images/Util.pm

Criterion	Covered	Total	%
statement	76	87	87.3
branch	31	48	64.5
condition	6	10	60.0
subroutine	11	13	84.6
pod	6	6	100.0
total	130	164	79.2

package Mojolicious::Plugin::Images::Util;
use Mojo::Base -base;
use 5.20.0;
use experimental 'signatures';

use Exporter 'import';
use IO::All;

our @EXPORT_OK = (
  qw(install_route expand_static calc_static plugin_log check_dir check_id));
our %EXPORT_TAGS = (all => \@EXPORT_OK);

my $INSECURE_IDS  = $ENV{IMAGES_ALLOW_INSECURE_IDS};
my $INSECURE_DIRS = $ENV{IMAGES_ALLOW_INSECURE_DIRS};

sub check_dir($dir, $app) {
  return $dir if $INSECURE_DIRS;
  my $msg
    = "insecure dir ${\ ( $dir // 'undef' ) }, set IMAGES_ALLOW_INSECURE_DIRS env to allow it";
  die $msg if !$dir || Mojo::Path->new($app->home)->contains("$dir");
  return $dir;
}

# maybe too hard
sub check_id($id) {
  return $id if $INSECURE_IDS;
  die "insecure id $id, set IMAGES_ALLOW_INSECURE_IDS env to allow it"
    unless $id =~ /^[\ \-\w\/]+$/;
  return $id;
}

sub plugin_log($app, $tmpl, @args) {
  my $msg = sprintf($tmpl, @args);
  $app->log->debug("Mojolicious::Plugin::Images $msg");
}

sub calc_static($dir, $url_prefix, $home) {
  return unless defined $url_prefix;

  $dir = io->dir($dir)->canonpath;
  $dir = $home->rel_dir($dir) unless io->dir($dir)->is_absolute;

  my $prefix = Mojo::Path->new($url_prefix)->canonicalize->to_route;
  $prefix = Mojo::Path->new($prefix)->leading_slash(0)->trailing_slash(0);

  $dir =~ s/$prefix$// or return;

  io->dir($dir)->canonpath;
}

sub expand_static($dir, $url_prefix, $app) {
  my $static_path = calc_static($dir, $url_prefix, $app->home) or return;
  $static_path = check_dir($static_path, $app);
  my $paths = $app->static->paths;
  push @$paths, $static_path unless grep { $_ eq $static_path } @$paths;
}

# install route /$prefix/(*key)-$suffix.$ext
sub install_route($app, $moniker, $opts) {
  my $placeholder = '(*images_id)';
  my $end = $opts->{suffix} // '';
  $end .= ".${\$opts->{ext}}" if $opts->{ext};
  my $path = Mojo::Path->new($opts->{url_prefix})->leading_slash(1)
    ->trailing_slash(1)->merge("${placeholder}${end}");

  plugin_log($app, "Installing route GET $path for Images '$moniker'");
  $app->routes->get("$path")->to(cb => sub { _action(shift, $moniker) });
}

sub _action($c, $moniker) {
  my $id  = $c->stash('images_id');
  my $img = $c->images->$moniker;

  plugin_log($c->app, "Generating $moniker: $id");
  return $c->reply->static($img->url($id))
    if $img->exists($id) || $img->sync($id);

  return $c->reply->not_found;
}

1;

__END__