File Coverage

blib/lib/Mojolicious/Plugin/Iconify.pm

Criterion	Covered	Total	%
statement	32	41	78.0
branch	12	26	46.1
condition	7	18	38.8
subroutine	6	7	85.7
pod	1	1	100.0
total	58	93	62.3

package Mojolicious::Plugin::Iconify;

use Mojo::Base 'Mojolicious::Plugin';
use Mojo::DOM::HTML;
use Mojo::ByteStream;

our $VERSION = '1.02';

sub register {

    my ( $self, $app, $config ) = @_;

    $app->helper(
        icon => sub {

            my ( $self, $icon, %params ) = @_;
            return unless $icon;

            my %iconify_params = (
                'class'     => 'iconify',
                'data-icon' => $icon,
            );

            foreach my $param ( keys %params ) {

                my $value = $params{$param};

                if ( $param eq 'size' ) {
                    $iconify_params{'data-width'}  = $value;
                    $iconify_params{'data-height'} = $value;
                }

                if ( $param eq 'inline' ) {
                    $iconify_params{'data-inline'} = ( $value == 0 ) ? 'false' : 'true';
                }

                if ( $param eq 'block' ) {
                    $iconify_params{'data-inline'} = ( $value == 0 ) ? 'true' : 'false';
                }

                if ( $param eq 'width' || $param eq 'height' || $param eq 'flip' || $param eq 'align' ) {
                    $iconify_params{"data-$param"} = $value;
                }

                $iconify_params{'data-flip'} .= 'horizontal ' if ( $param eq 'flip_horizontal' );
                $iconify_params{'data-flip'} .= 'vertical '   if ( $param eq 'flip_vertical' );
                $iconify_params{'data-rotate'} = $value . 'deg' if ( $param eq 'rotate' );

                # Core HTML attributes

                if ( $param eq 'class' ) {
                    $iconify_params{'class'} .= " $value";
                }

                if ( $param eq 'id' || $param eq 'title' || $param eq 'style' ) {
                    $iconify_params{$param} = $value;
                }

            }

            if ( defined $iconify_params{'data-flip'} ) {
                $iconify_params{'data-flip'} =~ s/\s$//;
            }

            return _tag( 'span', %iconify_params );

        }
    );

    $app->helper(
        iconify_js => sub {

            my ( $self, $url ) = @_;

            my $iconify_version = '1.0.3';
            my $iconify_js_url  = $url || "https://code.iconify.design/1/$iconify_version/iconify.min.js";

            return _tag( 'script', 'src' => $iconify_js_url );

        }
    );
}

sub _tag { Mojo::ByteStream->new( Mojo::DOM::HTML::tag_to_html(@_) ) }

__END__