File Coverage

blib/lib/Mojolicious/Plugin/Host.pm

Criterion	Covered	Total	%
statement	44	45	97.7
branch	25	26	96.1
condition	6	6	100.0
subroutine	8	8	100.0
pod	1	1	100.0
total	84	86	97.6

package Mojolicious::Plugin::Host;
use Mojo::Base 'Mojolicious::Plugin';
use Carp ();
use Mojo::Util ();

our $VERSION = '0.01';

sub register {
    my (undef, $app, $config) = @_;

    my ($helper, $www) = _parse_and_validate_config($config);
    my $sub;
    if (not defined $www) {
        $sub = sub { $_[0]->req->url->to_abs->host };
    } elsif ($www eq 'always') {
        $sub = sub {
            my $host = $_[0]->req->url->to_abs->host;
            if (index($host, 'www.') != 0) {
                $host = "www.$host";
            }

            return $host;
        };
    } elsif ($www eq 'never') {
        $sub = sub {
            my $host = $_[0]->req->url->to_abs->host;
            if (index($host, 'www.') == 0) {
                substr $host, 0, 4, '';
            }

            return $host;
        };
    } else {
        Carp::croak qq{unknown value provided for www: '$www'};
    }

    $app->helper($helper => $sub);
}

sub _parse_and_validate_config {
    my ($config) = @_;

    my $helper;
    if (exists $config->{helper}) {
        $helper = delete $config->{helper};

        my $ref = ref $helper;
        Carp::croak qq{helper must be a string, but was '$ref'} if $ref;
        Carp::croak 'helper must be non-empty' if not defined $helper or $helper eq '';
    } else {
        $helper = 'host';
    }

    my $www;
    if (exists $config->{www}) {
        $www = delete $config->{www};

        my $ref = ref $www;
        Carp::croak qq{www must be a string, but was '$ref'} if $ref;
        Carp::croak 'www must be non-empty' if not defined $www or $www eq '';
        Carp::croak qq{www must be either 'always' or 'never', but was '$www'}
            unless grep { $www eq $_ } 'always', 'never';
    }

    Carp::croak 'unknown keys/values: ' . Mojo::Util::dumper $config if %$config;

    return $helper, $www;
}

1;
__END__