File Coverage

blib/lib/Mojolicious/Plugin/Gzip.pm

Criterion	Covered	Total	%
statement	36	36	100.0
branch	15	16	93.7
condition	23	26	88.4
subroutine	5	5	100.0
pod	1	1	100.0
total	80	84	95.2

package Mojolicious::Plugin::Gzip;
use Mojo::Base 'Mojolicious::Plugin';
use Mojo::Util qw/gzip/;
use Scalar::Util qw/reftype/;

our $VERSION = '0.03';

sub register {
    my (undef, $app, $config) = @_;

    my $min_size;
    if (defined $config) {
        die 'config must be a hash reference'
            unless reftype($config) eq 'HASH';
        if (keys %$config) {
            $min_size = delete $config->{min_size} // '';
            die 'invalid key passed to Mojolicious::Plugin::Gzip (only min_size is allowed)'
                if keys %$config;
            die 'min_size must be a positive integer'
                unless $min_size =~ /^\d+$/ and $min_size > 0;
        }
    }
    $min_size //= 860;

    $app->hook(after_dispatch => sub {
        my ($c) = @_;
        my $req = $c->req;
        my $res = $c->res;

        my $accept_encoding = $req->headers->accept_encoding // '';
        my $body = $res->body;
        my $body_size = $res->body_size // 0;

        return unless $accept_encoding =~ /gzip/i
                and $body_size >= $min_size
                and $res->code == 200
                and not $res->headers->content_encoding;

        if (my $etag = $res->headers->etag) {
            if (length $etag > 2 and substr($etag, 0, 1) eq '"' and substr($etag, -1, 1) eq '"') {
                $etag = substr($etag, 1, length($etag) - 2);
            } else {
                $app->log->warn("Found either empty ETag or ETag not surrounded by quotes: '$etag'");
            }

            $res->headers->etag(qq{"$etag-gzip"});
        }

        my $zipped_body = gzip $body;
        $res->body($zipped_body);
        $res->headers->content_length(length $zipped_body);
        $res->headers->append(Vary => 'Accept-Encoding');
        $res->headers->content_encoding('gzip');
    });
}

1;
__END__