File Coverage

blib/lib/Mojolicious/Plugin/GoogleFontProxy.pm

Criterion	Covered	Total	%
statement	34	34	100.0
branch	4	6	66.6
condition	4	6	66.6
subroutine	5	5	100.0
pod	1	1	100.0
total	48	52	92.3

package Mojolicious::Plugin::GoogleFontProxy;

# ABSTRACT: a small proxy that can be useful when you embed gists in your website

use Mojo::Base 'Mojolicious::Plugin';

our $VERSION = '0.02';

our $CSS_URL_FORMAT    = 'https://fonts.googleapis.com/css?family=%s';
our $FONT_URL_FORMAT   = 'https://fonts.gstatic.com/s/%s';
our $USER_AGENT_STRING = '';

sub register {
    my ($self, $app, $config) = @_;

    if ( !$config->{no_types} ) {
        $app->types->type( 'woff2' => 'font/woff2' );
        $app->types->type( 'woff'  => 'font/woff' );
        $app->types->type( 'ttf'   => 'font/ttf' );
        $app->types->type( 'otf'   => 'font/opentype' );
    }

    $app->hook(
        after_render => sub {
            my ($c, $content, $format) = @_;

            return if !$format;
            return if $format ne 'html' && $format ne 'css';

            $$content =~ s{
                https://fonts.googleapis.com/css\?family=(.*?)(['"])
            }{$c->url_for( 'google-proxy-css', file => $1 ) . $2;}xge;
        }
    );

    $app->routes->get( '/google/css/*file' )->to( cb => sub {
        my $c = shift;

        $c->render_later;

        my $url = sprintf $CSS_URL_FORMAT, $c->param('file');
        my $ua_string = $USER_AGENT_STRING || $c->tx->req->headers->user_agent;

        $c->ua->get( $url => { 'User-Agent' => $ua_string } => sub {
            my ($ua, $tx) = @_;

            my $body = $tx->res->body;
            $body    =~ s{
                https?://fonts\.gstatic\.com/s/(.*?)\) \s* format\('(.*?)'\)
            }{$c->url_for('google-proxy-font', file => $1, fformat => $2) . ") format('$2')"}xmseg;

            return $c->render( data => $body, format => 'css' );
        });
    })->name( 'google-proxy-css' );

    $app->routes->get( '/google/font/:fformat/*file' )->to( cb => sub {
        my $c = shift;

        $c->render_later;

        my $url = sprintf $FONT_URL_FORMAT, $c->param('file');

        $c->ua->get( $url => sub {
            my ($ua, $tx) = @_;

            my $body = $tx->res->body;

            return $c->render( data => $body, format => $c->param('fformat') );
        });
    })->name( 'google-proxy-font' );
}

1;

__END__