File Coverage

blib/lib/Mojolicious/Plugin/GistGithubProxy.pm

Criterion	Covered	Total	%
statement	20	28	71.4
branch	3	4	75.0
condition			n/a
subroutine	4	5	80.0
pod	1	1	100.0
total	28	38	73.6

package Mojolicious::Plugin::GistGithubProxy;

# ABSTRACT: Mojolicious::Plugin::GistGithubProxy - a small proxy that can be useful when you embed gists in your website

use Mojo::Base 'Mojolicious::Plugin';

our $VERSION = '0.01';

our $GIST_URL_FORMAT = 'https://gist.github.com/%s/%s.js?file=%s';

sub register {
    my ($self, $app, $config) = @_;

    $app->hook(
        after_render => sub {
            my ($c, $content, $format) = @_;

            return if !$format;
            return if $format ne 'html';

            $$content =~ s{
                https://gist\.github\.com/(.*?)/(.*?)\.js\?file=(.*?)"
            }{$c->url_for( 'github-proxy-gist', user => $1, id => $2, file => $3 ) . '"';}xge;
        }
    );

    $app->routes->get( '/github/gist/:user/:id/*file', $config )->to( cb => sub {
        my $c = shift;

        $c->render_later;

        my $url = sprintf $GIST_URL_FORMAT, $c->param('user'), $c->param('id'), $c->param('file');

        $c->ua->get( $url => sub {
            my ($ua, $tx) = @_;

            my $body = $tx->res->body;
            $body    =~ s{
                https://assets-cdn.github.com/assets/gist-embed-(.*?)\.css
            }{$c->url_for('github-proxy-gist-asset', id => $1)}xmse;

            return $c->render( data => $body, format => 'js' );
        });
    })->name( 'github-proxy-gist' );

    $app->routes->get( '/github/gist/assets/:id' )->to( cb => sub {
        my $c = shift;

        $c->render_later;

        my $url = sprintf q~https://assets-cdn.github.com/assets/gist-embed-%s.css~, $c->param('id');
        $c->ua->get( $url => sub {
            my ($ua, $tx) = @_;

            my $body = $tx->res->body;
            return $c->render( data => $body, format => 'css' );
        });
    })->name( 'github-proxy-gist-asset' );

}

1;

__END__