File Coverage

blib/lib/Mojolicious/Plugin/FormFieldsFromJSON/Date.pm

Criterion	Covered	Total	%
statement	59	60	98.3
branch	19	26	73.0
condition	9	20	45.0
subroutine	8	8	100.0
pod	1	1	100.0
total	96	115	83.4

package Mojolicious::Plugin::FormFieldsFromJSON::Date;

use v5.10;
use Mojo::Base 'Mojolicious::Plugin';

our $VERSION = '1.00';

use Time::Piece;

sub register {
    my ($self, $app) = @_;

    1;
}

sub Mojolicious::Plugin::FormFieldsFromJSON::_date {
    my ($self, $c, $field, %params) = @_;

    my $name         = $field->{name} // $field->{label} // '';
    my $id           = $field->{id} // $name;
    my %local_params = %{ $params{$name} || {} };

    my $requested = ( $c->param( $name . '-day' ) ) ?
       ( sprintf "%04d-%02d-%02d",
           $c->param( $name . '-year' ),
           $c->param( $name . '-month' ),
           $c->param( $name . '-day' ),
       ) :
       "";

    my $now      = localtime;
    my $default  = $local_params{data} || $requested || $field->{data} || $now->ymd;
    my $selected = Time::Piece->strptime( $default, '%Y-%m-%d' );

    my $day = _day_dropdown(
        $c,
        %{ $field->{attributes} || {} },
        %local_params,
        day  => $selected->mday,
        id   => $id . '-day',
        name => $name . '-day',
    );

    my $month = _month_dropdown(
        $c,
        %{ $field->{attributes} || {} },
        %local_params,
        month => $selected->mon,
        id    => $id . '-month',
        name  => $name . '-month',
    );

    my $year = _year_dropdown(
        $c,
        startyear => $field->{startyear},
        %{ $field->{attributes} || {} },
        %local_params,
        year => $selected->year,
        id   => $id . '-year',
        name => $name . '-year',
    );

    my $format = $params{format} || $field->{format} || '%Y-%m-%d';
    $format =~ s/-//g;
    $format =~ s/\%Y/$year/g;
    $format =~ s/\%m/$month/g;
    $format =~ s/\%d/$day/g;

    return $format;
}

sub _day_dropdown {
    my ($c, %params) = @_;

    $c->param( $params{name}, '' );

    my @days = map{
        $c->param( $params{name} => sprintf("%02d", $_) ) if $_ == $params{day};
        [ $_ => sprintf("%02d", $_) ]
    }(1 .. 31);

    my $select = $c->select_field(
        $params{name},
        \@days,
        id => $params{id},
        %{ $params{attrs} || {} },
    );
}

sub _month_dropdown {
    my ($c, %params) = @_;

    $c->param( $params{name}, '' );

    my @months = map{
        $c->param( $params{name} => sprintf("%02d", $_) ) if $_ == $params{month};
        [ $_ => sprintf("%02d", $_) ]
    }(1 .. 12);

    my $select = $c->select_field(
        $params{name},
        \@months,
        id => $params{id},
        %{ $params{attrs} || {} },
    );
}

sub _year_dropdown {
    my ($c, %params) = @_;

    my $now   = localtime;
    my $base  = ( $params{startyear} // $now->year );
    my $start = $base - ( $params{past} // 1 );
    my $stop  = $base + ( $params{future} // 5 );

    $c->param( $params{name}, '' );

    my $has_year;
    my @years = map{
        $has_year++ if $_ == $params{year};
        $c->param( $params{name} => $params{year} ) if $_ == $params{year};
        [ $_ => $_ ]
    }($start .. $stop);

    if ( !$has_year ) {
        unshift @years, [ $params{year} => $params{year}, { selected => 'selected' } ];
    }

    my $select = $c->select_field(
        $params{name},
        \@years,
        id => $params{id},
        %{ $params{attrs} || {} },
    );
}

1;

__END__