File Coverage

lib/Mojolicious/Plugin/Data/Validate/WithYAML.pm

Criterion	Covered	Total	%
statement	47	47	100.0
branch	16	16	100.0
condition			n/a
subroutine	10	10	100.0
pod	1	1	100.0
total	74	74	100.0

package Mojolicious::Plugin::Data::Validate::WithYAML;

# ABSTRACT: validate form input with Data::Validate::WithYAML

use strict;
use warnings;

use parent 'Mojolicious::Plugin';

use Carp;
use Data::Validate::WithYAML;
use File::Spec;

our $VERSION = 0.05;

sub register {
    my ($self, $app, $config) = @_;

    $config->{conf_path} = $app->home if !$config->{conf_path};
    $config->{no_steps}  = 1          if !defined $config->{no_steps};

    $app->helper( 'validate' => sub {
        my ($c, $file) = @_;

        my $validator = _validator( $file, $config );
        my %params    = %{ $c->req->params->to_hash };
        my %errors    = $validator->validate( %params );

        my $prefix = exists $config->{error_prefix} ?
            $config->{error_prefix} :
            'ERROR_';

        my %prefixed_errors = map{ ( "$prefix$_" => $errors{$_} ) } keys %errors;

        return %prefixed_errors;
    });

    $app->helper( 'fieldinfo' => sub {
        my ($c, $file, $field, $subinfo) = @_;

        my $validator = _validator( $file, $config );
        my $info      = $validator->fieldinfo( $field );

        return if !$info;

        return $info if !$subinfo;
        return $info->{$subinfo};
    });
}

sub _validator {
    my ($file, $config) = @_;

    if ( !$file ) {
        my @caller = caller(3);
        $file      = (split /::/, $caller[3])[-1];
    }

    my $path = File::Spec->rel2abs(
        File::Spec->catfile( $config->{conf_path}, $file . '.yml' )
    );

    croak "$path does not exist" if !-e $path;

    my $validator = Data::Validate::WithYAML->new(
        $path,
        %{$config},
    ) or croak $Data::Validate::WithYAML::errstr;

    return $validator;
}

1;

__END__