File Coverage

blib/lib/Mojolicious/Plugin/CascadingConfig.pm

Criterion	Covered	Total	%
statement	27	27	100.0
branch	14	14	100.0
condition	6	6	100.0
subroutine	3	3	100.0
pod	1	1	100.0
total	51	51	100.0

package Mojolicious::Plugin::CascadingConfig;
use Mojo::Base 'Mojolicious::Plugin::Config';

our $VERSION = '0.02';

sub register {
    my ($self, $app, $plugin_conf) = @_;
    die 'Modes must be a non-empty array reference if provided'
        if defined $plugin_conf->{modes} and (not ref $plugin_conf->{modes} eq 'ARRAY' or not @{$plugin_conf->{modes}});

    # Override
    $app->defaults(config => $app->config);
    return $app->config if $app->config->{config_override};

    my @modes = @{$plugin_conf->{modes} || ['production', 'development']};
    my $moniker = $app->moniker;
    my $app_mode = $app->mode;
    my $config = {};
    for my $mode (@modes) {
        $config = $self->_load_and_merge_mode_config($app, $mode, $moniker, $plugin_conf, $config, 1);

        if ($mode eq $app_mode) {
            return $app->config($config)->config;
        }
    }

    $config = $self->_load_and_merge_mode_config($app, $app->mode, $moniker, $plugin_conf, $config, undef);
    return $app->config($config)->config;
}

sub _load_and_merge_mode_config {
    my ($self, $app, $mode, $moniker, $plugin_conf, $config, $require) = @_;

    my $filename = $mode eq 'production' ? "$moniker.conf" : "$moniker.$mode.conf";
    my $file = $app->home->child($filename);

    if (not -e $file) {
        if ($require) {
            die qq{Configuration file "$file" missing, maybe you need to create it?};
        } else {
            return $config;
        }
    }

    my $mode_config = $self->load($file, $plugin_conf, $app);
    return {%$config, %$mode_config};
}

1;
__END__